Mercurial > public > hwos_code
annotate src/isr.asm @ 642:a9a0188091e4
fix rare upgrade issue with OSTC sport 2019 hardware
| author | heinrichsweikamp |
|---|---|
| date | Thu, 14 Jan 2021 16:24:07 +0100 |
| parents | 8c1f1f334275 |
| children | 7d8a4c60ec1a 5b7fe7777425 |
| rev | line source |
|---|---|
| 0 | 1 ;============================================================================= |
| 2 ; | |
| 640 | 3 ; File isr.asm * combined next generation V3.11.1 |
| 0 | 4 ; |
| 5 ; INTERUPT subroutines | |
| 6 ; | |
| 7 ; Copyright (c) 2011, JD Gascuel, HeinrichsWeikamp, all right reserved. | |
| 8 ;============================================================================= | |
| 9 ; HISTORY | |
| 10 ; 2011-05-24 : [jDG] Cleanups from initial Matthias code. | |
| 11 | |
| 275 | 12 #include "hwos.inc" |
| 582 | 13 #include "shared_definitions.h" ; Mailbox from/to p2_deco.c |
| 0 | 14 #include "ms5541.inc" |
| 15 #include "adc_lightsensor.inc" | |
| 623 | 16 |
| 17 extern restore_flash | |
| 0 | 18 |
| 634 | 19 |
| 0 | 20 ;============================================================================= |
| 634 | 21 ; Code to be placed at a fixed Position |
| 623 | 22 ; |
| 604 | 23 isr_high CODE 0x0008 ; high priority interrupts |
| 634 | 24 bra HighInt ; jump to ISR |
| 25 | |
| 26 isr_low CODE 0x00018 ; low priority interrupts *** not used *** | |
| 27 retfie FAST ; do an immediate return from IRQ | |
| 28 ; | |
| 29 ;============================================================================= | |
| 623 | 30 |
| 0 | 31 |
| 634 | 32 ;----------------------------------------------------------------------------- |
| 33 ; Interrupt Dispatcher Entry Point | |
| 623 | 34 ; |
| 0 | 35 HighInt: |
| 623 | 36 ; initialize interrupt code |
| 37 banksel isr_backup ; default bank for all ISR code is bank ISR data | |
| 629 | 38 movff PRODL,PROD_backup+0 ; back-up PRODL |
| 39 movff PRODH,PROD_backup+1 ; back-up PRODH | |
| 623 | 40 ; serve buttons |
| 41 btfsc PIR1,TMR1IF ; timer 1 interrupt (button hold-down timer)? | |
| 42 rcall timer1int ; YES - reset timer | |
| 640 | 43 btfsc PIR5,TMR4IF ; timer 4 interrupt (button debounce) |
| 44 rcall timer4int ; YES, serve the interrupt | |
| 623 | 45 btfsc INTCON,INT0IF ; right button activity? |
| 46 rcall isr_switch_right ; YES - check right switch | |
| 47 btfsc INTCON3,INT1IF ; left button activity? | |
| 48 rcall isr_switch_left ; YES - check left switch | |
| 0 | 49 |
| 623 | 50 IFDEF _external_sensor |
| 51 ; serve IR/S8 link timer | |
| 52 btfsc PIR3,RC2IF ; UART 2 interrupt? | |
| 53 rcall isr_uart2 ; YES - get a byte from the IR/S8 link | |
| 54 btfsc PIR2,TMR3IF ; timer 3 interrupt? | |
| 55 rcall isr_timer3 ; YES - check bytes received from IR/S8 link for being a valid telegram | |
| 629 | 56 ELSE |
| 57 bcf PIR3,RC2IF ; clear UART 2 interrupt | |
| 58 bcf PIR2,TMR3IF ; clear timer 3 interrupt | |
| 59 ; fill-up to keep code size identical to _external_sensor variant, see "Attention" below | |
| 60 nop | |
| 61 nop | |
| 623 | 62 ENDIF |
| 63 | |
| 64 ; serve pressure and temperature sensor | |
| 65 btfsc PIR5,TMR7IF ; timer 7 interrupt? | |
| 66 rcall isr_tmr7 ; YES - do every 62.5 ms tasks: read sensors, set CPU speed | |
| 67 | |
| 68 ; serve real-time clock (RTCC) | |
| 69 btfsc PIR3,RTCCIF ; real-time-clock interrupt? | |
| 70 rcall isr_rtcc ; YES - do every 1/2 s tasks: read RTC, trigger timed tasks, adjust CPU speed, gauge battery, etc. | |
| 113 | 71 |
| 623 | 72 ; clean up and exit |
| 629 | 73 movff PROD_backup+0,PRODL ; restore PRODL |
| 74 movff PROD_backup+1,PRODH ; restore PRODH | |
| 623 | 75 bsf trigger_isr_updates ; signal that the ISR had kicked in |
| 76 retfie FAST ; return from interrupt restoring BSR, STATUS and WREG | |
| 77 | |
| 113 | 78 |
| 634 | 79 ;----------------------------------------------------------------------------- |
| 80 ; CPU Speed Adjustment | |
| 623 | 81 ; |
| 82 isr_adjust_speed: | |
| 83 movff cpu_speed_request,cpu_speed_state ; acknowledge CPU speed request | |
| 0 | 84 |
| 623 | 85 btfsc speed_is_eco ; speed 'eco' requested? |
| 86 bra isr_set_speed_to_eco ; YES - set eco speed | |
| 87 btfsc speed_is_fastest ; NO - speed 'fastest' requested? | |
| 88 bra isr_set_speed_to_fastest ; YES - set fastest speed | |
| 89 ;bra isr_set_speed_to_normal ; NO - default to normal speed | |
| 0 | 90 |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
91 isr_set_speed_to_normal: |
| 629 | 92 clrf OSCTUNE ; switch off x4 PLL |
| 623 | 93 movlw b'01110010' ; select 16 MHz |
| 94 movwf OSCCON ; set prescaler | |
| 95 movlw T2CON_NORMAL ; PWM1 dimming factor for speed 'normal' | |
| 96 bra isr_adjust_speed_exit | |
| 97 | |
| 98 isr_set_speed_to_eco: | |
| 629 | 99 clrf OSCTUNE ; switch off x4 PLL |
| 623 | 100 movlw b'00110010' ; select 1 MHz |
| 101 movwf OSCCON ; set prescaler | |
| 102 movlw T2CON_ECO ; PWM1 dimming factor for speed 'eco' | |
| 103 bra isr_adjust_speed_exit | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
104 |
| 623 | 105 isr_set_speed_to_fastest: |
| 106 movlw b'01110010' ; select 16 MHz by default | |
| 107 btfsc lv_core ; on OSTC with low voltage core? | |
| 108 movlw b'01100010' ; YES - reduce to 8 MHz | |
| 109 movwf OSCCON ; set prescaler | |
| 629 | 110 bsf OSCTUNE,6 ; switch on x4 PLL -> 64 MHz on high voltage core, 32 MHz on low voltage core |
| 623 | 111 movlw T2CON_FASTEST ; PWM1 dimming factor for speed 'fastest' |
| 640 | 112 bra isr_adjust_speed_exit |
| 623 | 113 |
| 114 ; Attention: fill-up the gap between the end of this section | |
| 115 ; and the next section which starts at 0x00080 !! | |
| 640 | 116 nop |
| 117 | |
| 623 | 118 block_0_code_end: ; marker to find end of code in block 0 in linker report file |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
119 |
| 634 | 120 |
| 623 | 121 ;============================================================================= |
| 634 | 122 ; Code to be placed at a fixed Position: Jump-Vector for the Bootloader |
| 623 | 123 ; |
| 634 | 124 restore CODE 0x00080 ; restore first flash page from EEPROM |
| 125 | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
126 restore_flash_0x00080: |
| 582 | 127 goto restore_flash |
| 634 | 128 ; |
| 129 ;============================================================================= | |
| 130 | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
131 |
| 623 | 132 ;============================================================================= |
| 634 | 133 isr_handler CODE 0x00084 |
| 134 ;============================================================================= | |
| 135 | |
| 640 | 136 isr_adjust_speed_exit: |
| 137 movwf T2CON ; adjust PWM1 for LED dimming | |
| 138 btfss OSCCON,HFIOFS ; PLL stabilized? | |
| 139 bra isr_adjust_speed_exit ; NO - loop to give it some more time | |
| 140 return ; YES - done | |
| 141 | |
| 634 | 142 ;----------------------------------------------------------------------------- |
| 143 ; Handle digitally-attached external Sensors | |
| 144 ; | |
| 145 ; take a byte received on IR/S8 link and slot it into the RX buffer | |
| 623 | 146 ; |
| 147 IFDEF _external_sensor | |
| 148 | |
| 149 isr_uart2: | |
| 634 | 150 bcf PIR3,RC2IF ; clear UART 2 interrupt flag |
| 623 | 151 banksel RCREG2 ; RC*2 is outside access RAM |
| 152 movff RCREG2,isr_lo ; copy received byte to isr_lo | |
| 153 bcf RCSTA2,CREN ; clear receiver status | |
| 154 bsf RCSTA2,CREN ; ... | |
| 155 banksel isr_backup ; back to default ISR bank | |
| 156 movlw .18 ; size of the buffer | |
| 157 cpfslt ir_s8_counter ; number of received bytes < buffer size? | |
| 158 bra isr_uart2_1 ; NO - buffer full, do not store the byte | |
| 159 movf ir_s8_counter,W ; YES - copy number of received bytes to WREG | |
| 160 MOVII FSR0L,FSR0_backup ; - back-up FSR0 | |
| 161 lfsr FSR0,ir_s8_buffer ; - load base address of buffer | |
| 162 movff isr_lo,PLUSW0 ; - store received byte | |
| 163 MOVII FSR0_backup,FSR0L ; - restore FSR0 | |
| 164 incf ir_s8_counter,F ; - increment number of received bytes by 1 | |
| 165 isr_uart2_1: | |
| 634 | 166 movlw .253 ; reload timer 3, high byte |
| 623 | 167 movwf TMR3H ; ... |
| 634 | 168 clrf TMR3L ; reload timer 3, low byte |
| 169 bsf T3CON,TMR3ON ; restart timer | |
| 170 return ; done | |
| 623 | 171 |
| 172 | |
| 634 | 173 ;----------------------------------------------------------------------------- |
| 174 ; Timeout on IR/S8 Link: check the Checksum and gather the received Data | |
| 623 | 175 ; |
| 176 isr_timer3: | |
| 604 | 177 bcf T3CON,TMR3ON ; stop timer 3 |
| 634 | 178 movlw .15 ; a IR telegram has 15 bytes |
| 604 | 179 cpfseq ir_s8_counter ; got exactly 15 bytes? |
| 623 | 180 bra isr_timer3_1 ; NO - test for 16 bytes |
| 604 | 181 bra isr_timer3_ir ; YES - got 15 bytes, compute local checksum |
| 0 | 182 isr_timer3_1: |
| 634 | 183 movlw .16 ; a IR telegram may also have 16 bytes, with last byte 0x00 |
| 604 | 184 cpfseq ir_s8_counter ; got exactly 16 bytes? |
| 623 | 185 bra isr_timer3_2 ; NO - test for 17 bytes |
| 604 | 186 tstfsz ir_s8_buffer+.15 ; YES - last byte = 0x00 ? |
| 634 | 187 bra isr_timer3_exit ; NO - exit |
| 604 | 188 bra isr_timer3_ir ; YES - got 16 bytes, compute local checksum |
| 113 | 189 isr_timer3_2: |
| 634 | 190 movlw .17 ; a S8 telegram has 17 bytes |
| 604 | 191 cpfseq ir_s8_counter ; got exactly 17 bytes? |
| 192 bra isr_timer3_exit ; NO - exit | |
| 193 bra isr_timer3_s8 ; YES - S8 data | |
| 0 | 194 |
| 634 | 195 ; process telegram received on IR link |
| 623 | 196 isr_timer3_ir: |
| 634 | 197 movlw .12 ; compute checksum over 1st and next 12 bytes |
| 623 | 198 rcall compute_IR_S8_checksum ; compute checksum |
| 634 | 199 tstfsz ir_s8_counter ; checksum ok? |
| 200 bra isr_timer3_exit ; NO - discard data | |
| 0 | 201 |
| 634 | 202 ; copy received data to respective variables |
| 623 | 203 movff ir_s8_buffer+.1, hud_status_byte |
| 204 movff ir_s8_buffer+.2, sensor1_mv+0 | |
| 205 movff ir_s8_buffer+.3, sensor1_mv+1 | |
| 206 movff ir_s8_buffer+.4, sensor2_mv+0 | |
| 207 movff ir_s8_buffer+.5, sensor2_mv+1 | |
| 208 movff ir_s8_buffer+.6, sensor3_mv+0 | |
| 209 movff ir_s8_buffer+.7, sensor3_mv+1 | |
| 210 movff ir_s8_buffer+.8, sensor1_ppO2 | |
| 211 movff ir_s8_buffer+.9, sensor2_ppO2 | |
| 212 movff ir_s8_buffer+.10,sensor3_ppO2 | |
| 582 | 213 movff ir_s8_buffer+.11,hud_battery_mv+0 |
| 214 movff ir_s8_buffer+.12,hud_battery_mv+1 | |
| 0 | 215 |
| 623 | 216 bsf hud_connection_ok ; set manually for hwHUD w/o the HUD module |
| 217 bra isr_timer3_reload ; reload timer and exit | |
| 218 | |
| 634 | 219 ; process telegram received on S8 link |
| 623 | 220 isr_timer3_s8: |
| 634 | 221 movlw .14 ; compute checksum over 1st and next 14 bytes |
| 623 | 222 rcall compute_IR_S8_checksum ; compute checksum |
| 634 | 223 tstfsz ir_s8_counter ; checksum ok? |
| 224 bra isr_timer3_exit ; NO - discard data | |
| 623 | 225 |
| 634 | 226 ; copy received data to respective variables |
| 227 movff ir_s8_buffer+.3, hud_status_byte ; also sets hud_connection_ok flag | |
| 623 | 228 movff ir_s8_buffer+.13,hud_battery_mv+0 |
| 229 movff ir_s8_buffer+.14,hud_battery_mv+1 | |
|
227
03946aa48fa5
NEW: Support for hwHUD without the LED module
heinrichsweikamp
parents:
204
diff
changeset
|
230 |
| 634 | 231 ; btfsc trigger_S8_data_update ; last data already processed? |
| 232 ; bra isr_timer3_exit ; NO - skip copying new data (and not reload the timeout) | |
| 623 | 233 bsf trigger_S8_data_update ; YES - set flag for new data available |
| 582 | 234 |
| 634 | 235 ; copy more received data to respective variables |
| 623 | 236 movff ir_s8_buffer+.4, s8_rawdata_sensor1+0 |
| 237 movff ir_s8_buffer+.5, s8_rawdata_sensor1+1 | |
| 238 movff ir_s8_buffer+.6, s8_rawdata_sensor1+2 | |
| 239 movff ir_s8_buffer+.7, s8_rawdata_sensor2+0 | |
| 240 movff ir_s8_buffer+.8, s8_rawdata_sensor2+1 | |
| 241 movff ir_s8_buffer+.9, s8_rawdata_sensor2+2 | |
| 242 movff ir_s8_buffer+.10,s8_rawdata_sensor3+0 | |
| 243 movff ir_s8_buffer+.11,s8_rawdata_sensor3+1 | |
| 244 movff ir_s8_buffer+.12,s8_rawdata_sensor3+2 | |
| 245 | |
| 246 isr_timer3_reload: | |
| 634 | 247 movlw ir_timeout_value ; get timeout value (in multiples of 62.5 ms) |
| 248 movwf ir_s8_timeout ; reload timeout counter | |
| 0 | 249 isr_timer3_exit: |
| 634 | 250 clrf ir_s8_counter ; clear number of received bytes |
| 251 bcf PIR2,TMR3IF ; clear IRQ flag | |
| 252 return ; done | |
| 0 | 253 |
| 254 | |
| 634 | 255 ;----------------------------------------------------------------------------- |
| 256 ; Helper Function - Compute Checksum on Data in RX Buffer | |
| 623 | 257 ; |
| 258 compute_IR_S8_checksum: | |
| 259 movwf ir_s8_counter ; initialize loop counter from WREG | |
| 634 | 260 MOVII FSR0L,FSR0_backup ; back-up FSR0 |
| 261 lfsr FSR0,ir_s8_buffer ; load base address of the receive buffer | |
| 262 movff POSTINC0,isr_mpr+0 ; initialize low byte of the calculated checksum with first byte in buffer | |
| 263 clrf isr_mpr+1 ; clear the high byte of the calculated checksum | |
| 623 | 264 compute_IR_S8_checksum_loop: |
| 634 | 265 movf POSTINC0,W ; read next byte |
| 623 | 266 addwf isr_mpr+0,F ; add it to the to checksum, low byte |
| 267 movlw .0 ; no explicit data to add to the high byte... | |
| 268 addwfc isr_mpr+1,F ; ... besides the carry | |
| 634 | 269 decfsz ir_s8_counter,F ; decrement number of bytes yet to do, all done? |
| 623 | 270 bra compute_IR_S8_checksum_loop ; NO - loop |
| 634 | 271 movf POSTINC0,W ; YES - read low byte of the received checksum |
| 272 cpfseq isr_mpr+0 ; - equal to low byte of the calculated checksum? | |
| 273 incf ir_s8_counter,F ; NO - mark a checksum error | |
| 274 movf POSTINC0,W ; - read high byte of the received checksum | |
| 275 cpfseq isr_mpr+1 ; - equal to high byte of the calculated checksum? | |
| 276 incf ir_s8_counter,F ; NO - mark a checksum error | |
| 277 MOVII FSR0_backup,FSR0L ; - restore FSR0 | |
| 278 return ; - done | |
| 113 | 279 |
| 623 | 280 ENDIF ; _external_sensor |
| 113 | 281 |
| 640 | 282 |
| 283 ;----------------------------------------------------------------------------- | |
| 284 ; Timer 4 - Button debounce (For new digital piezo circuit) | |
| 285 | |
| 286 timer4int: | |
| 287 bcf PIR5,TMR4IF | |
| 288 decfsz debounce_counter,F | |
| 289 return | |
| 290 bcf T4CON,TMR4ON ; Stop timer 4 | |
| 291 clrf TMR4 ; reset | |
| 292 | |
| 293 movff opt_cR_button_right,WREG ; 20-100; mH: opt_cR_button_right will also affect left button | |
| 294 bcf STATUS,C ; clear carry bit | |
| 295 rrcf WREG ; /2 -> 10-50 | |
| 296 bcf STATUS,C ; clear carry bit | |
| 297 rrcf WREG ; /2 -> 5-25 | |
| 298 decf WREG,W ; -1 | |
| 299 decf WREG,W ; -1 | |
| 300 decf WREG,W ; -1 -> 2-22 | |
| 301 | |
| 302 ; movlw .5 ; initial delay | |
| 303 movwf debounce_counter ; multiples of 16ms | |
| 304 return | |
| 305 | |
| 306 timer4_restart: | |
| 307 movlw .5 ; extra delay | |
| 308 movwf debounce_counter | |
| 309 clrf TMR4 ; reset | |
| 310 bcf INTCON3,INT1IF ; clear ext. int 1 request | |
| 311 bcf INTCON,INT0IF ; clear ext. int 0 request | |
| 312 bsf INTCON,INT0IE ; enable INT0 IRQ | |
| 313 bsf INTCON3,INT1IE ; enable INT1 IRQ | |
| 314 return | |
| 0 | 315 |
| 634 | 316 ;----------------------------------------------------------------------------- |
| 317 ; Tasks every 62.5 ms: Buttons, Dimming, Pressure/Temperature Sensor and CPU Speed | |
| 623 | 318 ; |
| 319 isr_tmr7: | |
| 634 | 320 bcf PIE5,TMR7IE ; disable IRQs by TMR7 |
| 0 | 321 |
| 634 | 322 banksel 0xF16 ; TMR7H/L are not part of the access RAM |
| 323 movlw .248 ; reload timer 7, high byte (8x256 ticks -> 62.5 ms) | |
| 324 movwf TMR7H ; ... (keep low byte running ) | |
| 325 | |
| 640 | 326 btfss update_surface_pressure ; shall update the surface pressure? |
| 327 bra isr_tmr7_1 ; NO - skip | |
| 328 bcf update_surface_pressure ; YES - clear request flag | |
| 329 MOVII pressure_abs_ref,pressure_surf ; - update surface pressure | |
| 636 | 330 |
| 640 | 331 isr_tmr7_1: |
| 634 | 332 call get_analog_switches ; get analog readings - bank-safe, but CAUTION: returns in bank common |
| 333 banksel isr_backup ; back to ISR default bank | |
| 623 | 334 |
| 634 | 335 btfss INTCON3,INT1IE ; external IRQ 1 enabled? |
| 640 | 336 bra isr_tmr7_2 ; NO - skip next |
| 634 | 337 btfsc analog_sw2_pressed ; YES - analog switch 2 pressed? |
| 338 rcall isr_switch_left ; NO - get digital readings of left switch | |
| 640 | 339 |
| 340 isr_tmr7_2: | |
| 634 | 341 btfss INTCON,INT0IE ; external IRQ 0 enabled? |
| 640 | 342 bra isr_tmr7_3 ; NO - skip next |
| 634 | 343 btfsc analog_sw1_pressed ; YES - analog switch 1 pressed? |
| 344 rcall isr_switch_right ; NO - get digital readings of right switch | |
| 640 | 345 |
| 346 isr_tmr7_3: | |
| 347 btfsc block_sensor_interrupt ; sensor interrupts disabled? | |
| 634 | 348 bra sensor_int_state_exit ; YES - goto exit |
| 640 | 349 ;bra isr_tmr7_4 ; NO - continue |
| 350 | |
| 351 isr_tmr7_4: | |
| 623 | 352 movf max_CCPR1L,W ; dim value |
| 582 | 353 cpfseq CCPR1L ; = current PWM value? |
| 623 | 354 rcall isr_dimm_tft ; NO - adjust until max_CCPR1L = CCPR1L |
| 0 | 355 |
| 623 | 356 IFDEF _external_sensor |
| 640 | 357 |
| 634 | 358 decfsz ir_s8_timeout,F ; decrement IR/S8 timeout counter, became zero? |
| 640 | 359 bra isr_sensor_state2 ; NO - continue with sensor |
| 634 | 360 movlw ir_timeout_value ; YES - get timeout value (in multiples of 62.5 ms) |
| 361 movwf ir_s8_timeout ; - reload timeout timer | |
| 362 btfsc ext_input_optical ; - optical input in use? | |
| 640 | 363 bra isr_tmr7_5 ; YES - clear data |
| 634 | 364 TSTOSS opt_s8_mode ; NO - S8 input in use? |
| 640 | 365 bra isr_sensor_state2 ; NO - must be analog interface in use, keep data |
| 366 ;bra isr_tmr7_5 ; YES - clear data | |
| 634 | 367 |
| 640 | 368 isr_tmr7_5: |
| 623 | 369 clrf hud_status_byte ; S8/IR timeout clears all analog input readings to zero -> fallback will be triggered when in sensor mode |
| 370 CLRI hud_battery_mv ; clear battery voltage | |
| 582 | 371 |
| 623 | 372 banksel sensor1_mv ; select bank where sensor data are stored |
| 373 CLRI sensor1_mv ; clear all sensor data | |
| 374 CLRI sensor2_mv ; ... | |
| 375 CLRI sensor3_mv ; ... | |
| 376 clrf sensor1_ppO2 ; ... | |
| 377 clrf sensor2_ppO2 ; ... | |
| 378 clrf sensor3_ppO2 ; ... | |
| 628 | 379 banksel s8_rawdata_sensor1 |
| 380 CLRI s8_rawdata_sensor1 ; clear all sensor data (raw data) | |
| 381 clrf s8_rawdata_sensor1+2 | |
| 382 CLRI s8_rawdata_sensor2 ; clear all sensor data (raw data) | |
| 383 clrf s8_rawdata_sensor2+2 | |
| 384 CLRI s8_rawdata_sensor3 ; clear all sensor data (raw data) | |
| 385 clrf s8_rawdata_sensor3+2 | |
| 623 | 386 banksel isr_backup ; back to ISR default bank |
| 387 | |
| 388 bsf trigger_S8_data_update ; signal a data update | |
| 582 | 389 |
| 640 | 390 ENDIF ; _external_sensor |
| 0 | 391 |
| 640 | 392 isr_sensor_state2: |
| 623 | 393 btfss sensor_state_counter,0 ; every 1/4 second |
| 394 bsf trigger_quarter_second ; set flag | |
| 395 | |
| 396 btfss speed_is_normal ; CPU running on normal speed? | |
| 397 rcall isr_set_speed_to_normal ; NO - set CPU speed to normal | |
| 582 | 398 |
| 623 | 399 incf sensor_state_counter,F ; counts to eight for state machine |
| 0 | 400 |
| 623 | 401 ; State 1: clear flags and average registers, get temperature (51 us) and start pressure integration (73.5 us) |
| 402 ; State 2: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 403 ; State 3: get temperature (51 us) and start pressure integration (73.5 us) | |
| 404 ; State 4: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 405 ; State 5: get temperature (51 us) and start pressure integration (73.5 us) | |
| 406 ; State 6: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 407 ; State 7: get temperature (51 us) and start pressure integration (73.5 us) | |
| 408 ; State 8: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) and build average for half-second update of temperature and pressure | |
| 582 | 409 |
| 623 | 410 movff sensor_state_counter,WREG ; WREG used as temp here... |
| 582 | 411 dcfsnz WREG,F |
| 623 | 412 bra sensor_int_state1_plus_restart ; do state 1 |
| 582 | 413 dcfsnz WREG,F |
| 623 | 414 bra sensor_int_state2 ; do state 2 |
| 582 | 415 dcfsnz WREG,F |
| 623 | 416 bra sensor_int_state1 ; do state 3 |
| 582 | 417 dcfsnz WREG,F |
| 623 | 418 bra sensor_int_state2 ; do state 4 |
| 582 | 419 dcfsnz WREG,F |
| 623 | 420 bra sensor_int_state1 ; do state 5 |
| 582 | 421 dcfsnz WREG,F |
| 623 | 422 bra sensor_int_state2 ; do state 6 |
| 582 | 423 dcfsnz WREG,F |
| 623 | 424 bra sensor_int_state1 ; do state 7 |
| 425 | |
| 426 ; first, do state 2: | |
| 427 call get_pressure_value ; state 2: get pressure (51 us) | |
| 428 call get_temperature_start ; and start temperature integration (73.5 us) | |
| 429 call calculate_compensation ; calculate temperature compensated pressure (27 us) | |
| 0 | 430 |
| 634 | 431 ; build average for pressure |
| 623 | 432 bcf STATUS,C ; clear carry bit |
| 433 rrcf pressure_abs_avg+1 ; divide by 2 | |
| 634 | 434 rrcf pressure_abs_avg+0 ; ... |
| 623 | 435 bcf STATUS,C ; clear carry bit |
| 436 rrcf pressure_abs_avg+1 ; divide by 2, again | |
| 634 | 437 rrcf pressure_abs_avg+0 ; ... |
| 623 | 438 |
| 634 | 439 ; export averaged pressure |
| 440 MOVII pressure_abs_avg,pressure_abs ; export result | |
| 0 | 441 |
| 634 | 442 ; build average for temperature |
| 623 | 443 bcf STATUS,C ; clear carry bit by default |
| 444 btfsc temperature_avg+1,7 ; sign bit set? | |
| 445 bsf STATUS,C ; YES - copy sign bit to carry bit | |
| 446 rrcf temperature_avg+1 ; divide signed temperature by 2 | |
| 447 rrcf temperature_avg+0 ; ... | |
| 448 bcf STATUS,C ; clear carry bit by default | |
| 449 btfsc temperature_avg+1,7 ; sign bit set? | |
| 450 bsf STATUS,C ; YES - copy sign bit to carry bit | |
| 451 rrcf temperature_avg+1 ; divide signed temperature by 2 again (by 4 in total now) | |
| 452 rrcf temperature_avg+0 ; ... | |
| 453 MOVII temperature_avg,temperature_cur ; store final result | |
| 0 | 454 |
| 634 | 455 ; check for temperature change |
| 623 | 456 movf temperature_cur+0,W ; get current temperature, low byte |
| 457 cpfseq temperature_last+0 ; compare with last temperature, equal? | |
| 458 bra isr_sensor_state2_2 ; NO - temperature has changed | |
| 459 movf temperature_cur+1,W ; get current temperature, high byte | |
| 460 cpfseq temperature_last+1 ; compare with last temperature, equal? | |
| 461 bra isr_sensor_state2_2 ; NO - temperature has changed | |
| 462 bra isr_sensor_state2_3 ; YES to both - no change | |
| 0 | 463 |
| 464 isr_sensor_state2_2: | |
| 623 | 465 MOVII temperature_cur,temperature_last ; store current temperature as last temperature for next round |
| 466 bsf trigger_temp_changed ; set flag for temperature change | |
| 467 | |
| 0 | 468 isr_sensor_state2_3: |
| 629 | 469 ; reset state counter |
| 623 | 470 clrf sensor_state_counter ; reset state counter |
| 471 btfss reset_max_pressure ; shall clear the max pressure? | |
| 472 bra isr_sensor_state2_3a ; NO - continue with checking for pressure change | |
| 473 bcf reset_max_pressure ; YES - clear request flag | |
| 474 CLRI pressure_rel_max ; - clear max. pressure | |
| 0 | 475 |
| 623 | 476 isr_sensor_state2_3a: |
| 477 ; check for pressure change | |
| 478 movf pressure_abs+0,W ; get current pressure, low byte | |
| 479 cpfseq pressure_abs_last+0 ; compare with last pressure, equal? | |
| 480 bra isr_sensor_state2_4 ; NO - pressure has changed | |
| 481 movf pressure_abs+1,W ; YES - get current pressure, high byte | |
| 482 cpfseq pressure_abs_last+1 ; - compare with last pressure, equal? | |
| 483 bra isr_sensor_state2_4 ; NO - pressure has changed | |
| 484 bra isr_sensor_state2_5 ; YES - no change | |
| 485 | |
| 486 isr_sensor_state2_4: | |
| 487 MOVII pressure_abs,pressure_abs_last ; store current pressure as last pressure for next round | |
| 488 bsf trigger_pres_cur_changed ; signal a pressure change | |
| 489 | |
| 490 isr_sensor_state2_5: | |
| 491 ; compute relative pressure | |
| 492 movf pressure_surf+0,W ; get surface pressure, low byte | |
| 493 subwf pressure_abs+0,W ; WREG = pressure_abs - pressure_surf (low byte) | |
| 494 movwf pressure_rel_cur+0 ; store relative pressure, low byte | |
| 495 movf pressure_surf+1,W ; get surface pressure, high byte | |
| 496 subwfb pressure_abs+1,W ; WREG = pressure_abs - pressure_surf (high byte) | |
| 497 movwf pressure_rel_cur+1 ; store relative pressure, high byte | |
| 498 btfss STATUS,N ; relative pressure < 0 ? | |
| 499 bra isr_sensor_state2_6 ; NO - OK, keep result | |
| 500 CLRI pressure_rel_cur ; YES - set relative pressure to zero | |
| 0 | 501 |
| 623 | 502 isr_sensor_state2_6: |
| 503 ; check for new max relative pressure | |
| 504 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 505 subwf pressure_rel_max+0,W ; WREG = pressure_rel_max - pressure_rel_cur (low byte) | |
| 506 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 507 subwfb pressure_rel_max+1,W ; WREG = pressure_rel_max - pressure_rel_cur (high byte) | |
| 508 btfss STATUS,N ; result < 0, i.e. new max rel pressure? | |
| 509 bra isr_sensor_state2_6a ; NO | |
| 510 MOVII pressure_rel_cur,pressure_rel_max ; YES - set new max rel pressure | |
| 511 bsf trigger_pres_max_changed ; - signal a pressure max change | |
| 512 | |
| 513 isr_sensor_state2_6a: | |
| 0 | 514 |
| 623 | 515 IFDEF _min_depth_option |
| 516 ; check if min/max pressures shall be reset | |
| 517 btfss reset_trip_pressure ; shall reset the resettable min/max pressures? | |
| 518 bra isr_sensor_state2_6b ; NO | |
| 519 bcf reset_trip_pressure ; YES - clear request flag | |
| 520 CLRI pressure_rel_max_trip ; - set max pressure to zero | |
| 521 SETI pressure_rel_min_trip ; - set min pressure to biggest value possible | |
| 522 isr_sensor_state2_6b: | |
| 523 ; check for new resettable max relative pressure | |
| 524 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 525 subwf pressure_rel_max_trip+0,W ; WREG = pressure_rel_max - pressure_rel_cur (low byte) | |
| 526 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 527 subwfb pressure_rel_max_trip+1,W ; WREG = pressure_rel_max - pressure_rel_cur (high byte) | |
| 528 btfss STATUS,N ; result < 0, i.e. new max rel pressure? | |
| 529 bra isr_sensor_state2_6c ; NO - continue checking for min depth | |
| 530 MOVII pressure_rel_cur,pressure_rel_max_trip ; YES - set new max rel pressure | |
| 531 isr_sensor_state2_6c: | |
| 532 ; check for new resettable min relative pressure | |
| 533 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 534 subwf pressure_rel_min_trip+0,W ; WREG = pressure_rel_min - pressure_rel_cur (low byte) | |
| 535 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 536 subwfb pressure_rel_min_trip+1,W ; WREG = pressure_rel_min - pressure_rel_cur (high byte) | |
| 537 btfss STATUS,C ; result > 0, i.e. new min rel pressure? | |
| 538 bra sensor_int_state_exit ; NO - done | |
| 539 MOVII pressure_rel_cur,pressure_rel_min_trip ; YES - set new min rel pressure | |
| 540 ENDIF ; _min_depth_option | |
| 541 bra sensor_int_state_exit ; done | |
| 0 | 542 |
| 543 sensor_int_state1_plus_restart: | |
| 634 | 544 CLRI pressure_abs_avg ; clear average register for pressure |
| 545 CLRI temperature_avg ; clear average register for temperature | |
| 0 | 546 |
| 547 sensor_int_state1: | |
| 604 | 548 call get_temperature_value ; state 1: get temperature... |
| 549 call get_pressure_start ; ...and start pressure integration | |
| 582 | 550 bra sensor_int_state_exit |
| 0 | 551 |
| 552 sensor_int_state2: | |
| 604 | 553 call get_pressure_value ; state 2: get pressure (51 us)... |
| 554 call get_temperature_start ; ...and start temperature integration (73.5 us) | |
| 555 call calculate_compensation ; .. and calculate temperature compensated pressure (233 us) | |
| 582 | 556 |
| 0 | 557 sensor_int_state_exit: |
| 634 | 558 bcf PIR5,TMR7IF ; clear IRQ flag |
| 559 bsf PIE5,TMR7IE ; re-enable IRQs by TMR7 | |
| 623 | 560 bra isr_adjust_speed ; set/restore CPU speed and return |
| 561 | |
| 562 | |
| 634 | 563 ;----------------------------------------------------------------------------- |
| 564 ; Helper Function for Display Dimming | |
| 565 ; | |
| 623 | 566 isr_dimm_tft: ; adjust until max_CCPR1L = CCPR1L |
| 628 | 567 btfsc screen_type3 ; screen type 3 ? |
| 568 return ; YES - ignore, no dimming function with screen type 3 | |
| 623 | 569 btfsc tft_is_dimming ; is the display dimming? |
| 570 return ; YES - ignore | |
| 571 movf max_CCPR1L,W ; NO - proceed | |
| 628 | 572 cpfsgt CCPR1L ; - CCPR1L > max_CCPR1L ? |
| 573 bra isr_dimm_tft2 ; NO - dim up | |
| 574 decf CCPR1L,F ; YES - dim down | |
| 575 return ; - done | |
| 623 | 576 isr_dimm_tft2: |
| 628 | 577 movf max_CCPR1L,W ; |
| 578 sublw ambient_light_min_eco ; | |
| 623 | 579 cpfsgt CCPR1L ; CCPR1L > max_CCPR1L - ambient_light_min_eco ? |
| 580 bra isr_dimm_tft3 ; NO - dim up slow | |
| 628 | 581 movlw .10 ; YES - dim up faster (+10) |
| 582 addwf CCPR1L,F ; - add to dimming value | |
| 623 | 583 isr_dimm_tft3: |
| 628 | 584 incf CCPR1L,F ; - dim up (+1) |
| 585 return ; - done | |
| 623 | 586 |
| 582 | 587 |
| 634 | 588 ;----------------------------------------------------------------------------- |
| 589 ; RTC Interrupt (invoked every 0.5 Seconds) | |
| 623 | 590 ; |
| 591 isr_rtcc: | |
| 592 bcf PIR3,RTCCIF ; clear flag | |
| 593 bsf trigger_half_second ; set flag for a new 1/2 second has begun | |
| 594 btfsc reset_timebase ; shall reset the timebase? | |
| 595 bra isr_rtcc_1 ; YES - warp to new full second | |
| 596 btg timebase_0sec ; NO - toggle the 1/2 second timebase | |
| 597 btfsc timebase_0sec ; - did it toggled 1 -> 0 ? | |
| 598 return ; NO - on half second, done | |
| 0 | 599 |
| 623 | 600 isr_rtcc_1: |
| 601 ; new full second | |
| 602 bsf trigger_full_second ; set flag for a new 1/1 second has begun | |
| 603 | |
| 604 btfsc block_rtc_access ; ISR suspended from accessing the RTC? | |
| 605 bra isr_rtcc_2 ; YES | |
| 606 | |
| 607 banksel RTCCFG ; RTC registers are outside access RAM | |
| 582 | 608 bsf RTCCFG,RTCPTR1 |
| 623 | 609 bsf RTCCFG,RTCPTR0 |
| 610 banksel isr_backup ; back to ISR default bank | |
| 611 | |
| 612 movff RTCVALL,rtc_year ; read year in BCD | |
| 613 movff RTCVALH,rtc_day ; dummy read | |
| 614 movff RTCVALL,rtc_day ; read day in BCD | |
| 615 movff RTCVALH,rtc_month ; read month in BCD | |
| 616 movff RTCVALL,rtc_hour ; read hour in BCD | |
| 617 movff RTCVALH,rtc_secs ; dummy read | |
| 618 movff RTCVALL,rtc_secs ; read seconds in BCD | |
| 619 movff RTCVALH,rtc_mins ; read minutes in BCD | |
| 582 | 620 |
| 634 | 621 ; convert BCD to DEC and set registers |
| 623 | 622 movf rtc_mins,W |
| 623 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 624 movwf rtc_mins | |
| 625 movf rtc_secs,W | |
| 626 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 627 movwf rtc_secs | |
| 628 movf rtc_hour,W | |
| 629 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 630 movwf rtc_hour | |
| 631 movf rtc_month,W | |
| 632 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 633 movwf rtc_month | |
| 634 movf rtc_day,W | |
| 635 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 636 movwf rtc_day | |
| 637 movf rtc_year,W | |
| 638 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 639 movwf rtc_year | |
| 640 | |
| 641 isr_rtcc_2: | |
| 629 | 642 ; every full second - get ambient light level and set max_CCPR1L |
| 623 | 643 call get_ambient_level ; get ambient light level and set max_CCPR1L |
| 644 banksel isr_backup ; back to ISR default bank (for safety only) | |
| 645 | |
| 646 rcall isr_battery_gauge ; calculate the current charge consumption and add it to the battery gauge | |
| 647 rcall isr_update_uptime ; increment overall OSTC uptime | |
| 648 rcall isr_update_timeout ; process the timeout timer | |
| 649 | |
| 650 btfsc divemode ; in dive mode? | |
| 651 rcall isr_divemode_1sec ; YES - do the every second dive mode tasks | |
| 652 | |
| 629 | 653 ; increment surface interval counted in seconds |
| 623 | 654 btfsc divemode ; in dive mode? |
| 655 btfsc simulatormode ; YES - in simulator mode? | |
| 629 | 656 rcall inc_surface_interval_secs ; NO - YES - increment the surface interval (seconds timer) |
| 657 | |
| 658 ; reset the surface interval timers if requested | |
| 659 btfsc reset_surface_interval ; shall reset both surface interval timers? | |
| 634 | 660 rcall rst_surface_interval ; YES |
| 0 | 661 |
| 623 | 662 ; reset the timebase if requested |
| 663 btfss reset_timebase ; shall reset the timebase? | |
| 664 bra isr_rtcc_3 ; NO | |
| 665 bcf reset_timebase ; YES - clear request flag | |
| 666 clrf eventbase ; - clear all pending events | |
| 667 clrf timebase ; - clear all timebase flags | |
| 668 clrf timebase_secs ; - clear seconds timer | |
| 669 clrf timebase_mins ; - clear minutes timer | |
| 670 clrf simulator_time ; - clear minutes timer of simulator runtime as well | |
| 671 bsf trigger_half_second ; - set flag for a new 1/2 second has begun | |
| 672 bsf trigger_full_second ; - set flag for a new 1/1 second has begun | |
| 673 return ; - done | |
| 674 | |
| 675 isr_rtcc_3: | |
| 676 ; count-up the 2 seconds timebase timer | |
| 677 btg timebase_1sec ; toggle the 1 second timer bit | |
| 678 btfss timebase_1sec ; did it toggled 1 -> 0 ? | |
| 679 btg timebase_2sec ; YES - toggle the 2 seconds timer bit | |
| 680 | |
| 681 ; count-up the seconds timer | |
| 682 incf timebase_secs,F ; increment seconds timer (may temporary become 60 here) | |
| 683 movlw .59 ; max. for seconds timer | |
| 684 cpfsgt timebase_secs ; seconds timer > max.? | |
| 685 return ; NO - done | |
| 0 | 686 |
| 623 | 687 ; new full minute |
| 629 | 688 clrf timebase_secs ; reset timer |
| 689 bsf trigger_full_minute ; set flag for a new minute has begun | |
| 623 | 690 |
| 629 | 691 ; increment surface interval counted in minutes |
| 692 btfsc divemode ; in dive mode? | |
| 693 btfsc simulatormode ; YES - in simulator mode? | |
| 694 rcall inc_surface_interval_mins ; NO - YES - increment surface interval (minutes timer) | |
| 623 | 695 |
| 629 | 696 btfss simulatormode ; in simulator mode? |
| 697 bra isr_rtcc_4 ; NO | |
| 698 infsnz simulator_time,F ; YES - increment real runtime of the simulator, did wrap around (became zero)? | |
| 699 setf simulator_time ; YES - disallow wrap-around, keep at 255 instead | |
| 0 | 700 |
| 623 | 701 isr_rtcc_4: |
| 629 | 702 incf timebase_mins,F ; increment minutes timer |
| 703 movlw .59 ; max. for minutes timer | |
| 704 cpfsgt timebase_mins ; minutes timer > max.? | |
| 705 return ; NO - done | |
| 623 | 706 |
| 707 ; new full hour | |
| 629 | 708 clrf timebase_mins ; YES - reset timer |
| 709 bsf trigger_full_hour ; - set flag for a new hour has begun | |
| 710 return ; - done | |
| 623 | 711 |
| 712 ; increment overall OSTC uptime | |
| 713 isr_update_uptime: | |
| 634 | 714 incf uptime+0,F ; uptime++ |
| 715 clrf WREG ; ... | |
| 716 addwfc uptime+1,F ; ... | |
| 717 addwfc uptime+2,F ; ... | |
| 718 addwfc uptime+3,F ; ... | |
| 719 return ; done | |
| 582 | 720 |
| 623 | 721 ; process the timeout timer |
| 722 isr_update_timeout: | |
| 634 | 723 btfsc restart_timeout ; shall restart the timeout? |
| 623 | 724 bra isr_update_timeout_1 ; YES |
| 725 tstfsz isr_timeout_timer ; NO - timeout timer already at zero? | |
| 634 | 726 decfsz isr_timeout_timer,F ; NO - decrement timer, reached zero now? |
| 623 | 727 return ; YES / NO - nothing further to do |
| 728 bsf trigger_timeout ; YES - set timeout flag | |
| 729 return ; - done | |
| 730 isr_update_timeout_1: | |
| 634 | 731 bcf restart_timeout ; clear request flag |
| 623 | 732 bcf trigger_timeout ; clear pending timeout trigger, if any |
| 733 movff isr_timeout_reload,isr_timeout_timer ; reload timer | |
| 734 return ; done | |
| 0 | 735 |
| 634 | 736 |
| 737 ;----------------------------------------------------------------------------- | |
| 738 ; Calculate Charge drawn from the Battery | |
| 623 | 739 ; |
| 740 isr_battery_gauge: | |
| 741 btfsc block_battery_gauge ; access to battery gauge suspended? | |
| 742 return ; YES - done | |
| 743 MOVLI current_sleepmode,isr_mpr ; NO - default to sleep mode with 100µA/3600 -> nAs | |
| 744 btfss sleepmode ; - in sleep mode? | |
| 634 | 745 rcall isr_battery_gauge2 ; NO - compute current consumption into isr_lo and isr_hi |
| 746 movf isr_mpr+0,W ; - 48 bit add of isr_mpr:2 to battery_gauge:6 | |
| 747 addwf battery_gauge+0,F ; - ... | |
| 748 movf isr_mpr+1,W ; - ... | |
| 749 addwfc battery_gauge+1,F ; - ... | |
| 750 clrf WREG ; - ... | |
| 751 addwfc battery_gauge+2,F ; - ... | |
| 752 addwfc battery_gauge+3,F ; - ... | |
| 753 addwfc battery_gauge+4,F ; - ... | |
| 754 addwfc battery_gauge+5,F ; - ... | |
| 755 return ; - done | |
| 582 | 756 |
| 634 | 757 |
| 758 ;----------------------------------------------------------------------------- | |
| 759 ; Helper Function - compute current Consumption | |
| 760 ; | |
| 0 | 761 isr_battery_gauge2: |
| 634 | 762 ; Set consumption rate in nAs (nano Ampere x seconds) |
| 0 | 763 ; Example: |
| 623 | 764 ; MOVLI .55556,isr_mpr ; 0.2 Ah / 3600 seconds per hour * 1e9s = nAs |
| 765 ; | |
| 766 ; Remark: although all the constants are named current_xxxx, in reality they mean charge! | |
| 0 | 767 |
| 623 | 768 ; Calculate current consumption for LED backlight: 47*CCPR1L+272 (according to values in hwos.inc: 115*CCPR1L+216) |
| 631 | 769 movlw .70 ; screen type 3 has a fix backlight current slope |
| 770 btfss screen_type3 ; does the OSTC have a screen type 3 ? | |
| 771 movf CCPR1L,W ; NO - for screen types 0, 1 and 2 get the slope from CCPR1L | |
| 772 mullw current_backlight_multi ; multiply with backlight factor current_backlight_multi | |
| 773 ADDLI current_backlight_offset,PRODL ; add backlight offset current_backlight_offset | |
| 623 | 774 MOVII PRODL,isr_mpr ; copy result to isr_mpr |
| 0 | 775 |
| 634 | 776 ; add current for CPU and GPU |
| 623 | 777 ; cpu_speed_state = ECO 3.10 mA -> 861 nAs |
| 778 ; = NORMAL 5.50 mA -> 1528 nAs | |
| 779 ; = FASTEST 8.04 mA -> 2233 nAs | |
| 780 btfss speed_is_eco ; speed = eco ? | |
| 781 bra isr_battery_gauge3 ; NO | |
| 782 ADDLI current_speed_eco,isr_mpr ; YES - add current_speed_eco to isr_mpr | |
| 582 | 783 bra isr_battery_gauge5 |
| 0 | 784 isr_battery_gauge3: |
| 623 | 785 btfss speed_is_normal ; speed = normal? |
| 786 bra isr_battery_gauge4 ; NO | |
| 787 ADDLI current_speed_normal,isr_mpr ; YES - add current_speed_normal to isr_mpr | |
| 582 | 788 bra isr_battery_gauge5 |
| 0 | 789 isr_battery_gauge4: |
| 623 | 790 ADDLI current_speed_fastest,isr_mpr ; speed is fastest, add current_speed_fastest to isr_mpr |
| 0 | 791 isr_battery_gauge5: |
| 623 | 792 btfss ir_power ; IR enabled? |
| 793 bra isr_battery_gauge6 ; NO | |
| 794 ADDLI current_ir_receiver,isr_mpr ; YES - add current_ir_receiver to isr_mpr | |
| 0 | 795 isr_battery_gauge6: |
| 623 | 796 btfss compass_enabled ; compass active? |
| 797 bra isr_battery_gauge7 ; NO | |
| 798 ADDLI current_compass,isr_mpr ; YES - add current_compass to isr_mpr | |
| 0 | 799 isr_battery_gauge7: |
| 634 | 800 return ; done |
| 0 | 801 |
| 623 | 802 |
| 634 | 803 ;----------------------------------------------------------------------------- |
| 804 ; Every Second Tasks while in Dive Mode | |
| 623 | 805 ; |
| 0 | 806 isr_divemode_1sec: |
| 623 | 807 decfsz sampling_timer,F ; decrement sampling timer, became zero? |
| 808 bra isr_divemode_1sec_1 ; NO | |
| 809 bsf trigger_sample_divedata ; YES - set trigger flag for sampling dive data | |
| 810 movff sampling_rate,sampling_timer; - reload timer | |
| 0 | 811 |
| 623 | 812 isr_divemode_1sec_1: |
| 813 btfss reset_timebase ; shall reset the timebase? (request flag will be cleared later) | |
| 814 bra isr_divemode_1sec_2 ; NO | |
| 815 CLRI total_divetime_secs ; YES - reset total dive time, seconds (2 byte) | |
| 816 clrf counted_divetime_secs ; - reset counted dive time, seconds (1 byte) | |
| 817 CLRI counted_divetime_mins ; - reset counted dive time, minutes (2 byte) | |
| 818 clrf apnoe_dive_secs ; - reset apnoe dive time, seconds (1 byte) | |
| 819 clrf apnoe_dive_mins ; - reset apnoe dive time, minutes (1 byte) | |
| 820 bcf apnoe_at_surface ; - apnoe mode starts in submerged state | |
| 821 return ; - done | |
| 582 | 822 |
| 623 | 823 isr_divemode_1sec_2: |
| 824 INCI total_divetime_secs ; increase total dive time (regardless of start_dive_threshold) | |
| 825 btfss count_divetime ; shall the dive time be counted (regarding start_dive_threshold)? | |
| 629 | 826 bra isr_divemode_1sec_4 ; NO - too shallow / apnoe at surface |
| 623 | 827 incf counted_divetime_secs,F ; YES - increase dive time (displayed dive time) |
| 828 movlw d'59' ; - 60 seconds make a minute | |
| 829 cpfsgt counted_divetime_secs ; - next full minute reached? | |
| 629 | 830 bra isr_divemode_1sec_3 ; NO - continue |
| 623 | 831 clrf counted_divetime_secs ; YES - reset seconds to 0 |
| 832 INCI counted_divetime_mins ; - increase dive minutes | |
| 833 bsf divetime_longer_1min ; - set flag for dive time exceeding 1 minute | |
| 629 | 834 ;bra isr_divemode_1sec_3 ; - continue |
| 0 | 835 |
| 623 | 836 isr_divemode_1sec_3: ; submerged |
| 837 btfss FLAG_apnoe_mode ; in apnoe mode? | |
| 838 return ; NO - done | |
| 839 btfss apnoe_at_surface ; - been at surface before? | |
| 840 bra isr_divemode_1sec_3a ; NO - increment the dive time | |
| 841 bcf apnoe_at_surface ; YES - a new dive has begun | |
| 842 bsf apnoe_new_dive ; - signal a new dive has begun | |
| 843 clrf apnoe_surface_secs ; - clear surface seconds | |
| 844 clrf apnoe_surface_mins ; - clear surface minutes | |
| 845 clrf apnoe_dive_secs ; - clear dive seconds | |
| 846 clrf apnoe_dive_mins ; - clear dive minutes | |
| 847 MOVII pressure_rel_cur,pressure_rel_max ; - reset max pressure to current pressure | |
| 848 bsf trigger_pres_max_changed ; - signal a new maximum pressure | |
| 849 isr_divemode_1sec_3a: | |
| 850 incf apnoe_dive_secs,F ; increment dive time, seconds | |
| 851 movlw d'59' ; 60 seconds make a minute | |
| 852 cpfsgt apnoe_dive_secs ; next full minute reached? | |
| 853 return ; NO - done | |
| 854 clrf apnoe_dive_secs ; YES - reset seconds to 0 | |
| 855 incf apnoe_dive_mins,F ; - increment dive time, minutes | |
| 856 return ; - done | |
| 0 | 857 |
| 623 | 858 isr_divemode_1sec_4: ; at surface |
| 859 btfss FLAG_apnoe_mode ; in apnoe mode? | |
| 860 return ; NO - done | |
| 861 bsf apnoe_at_surface ; YES - memorize been at the surface | |
| 862 incf apnoe_surface_secs,F ; - increment surface time, seconds | |
| 863 movlw d'59' ; - 60 seconds make a minute | |
| 864 cpfsgt apnoe_surface_secs ; - next full minute reached? | |
| 865 return ; NO - done | |
| 866 clrf apnoe_surface_secs ; YES - reset seconds to 0 | |
| 867 incf apnoe_surface_mins,F ; - increment surface time, minutes | |
| 868 return ; - done | |
| 869 | |
| 870 | |
| 634 | 871 ;----------------------------------------------------------------------------- |
| 872 ; Helper Function - BCD to Binary conversion | |
| 873 ; | |
| 623 | 874 ; Input WREG = value in BCD |
| 875 ; Output WREG = value in binary | |
| 876 ; | |
| 877 isr_rtcc_convert_BCD_DEC: | |
| 634 | 878 movwf isr_lo ; copy BCD to isr_lo |
| 879 swapf isr_lo, W ; create swapped copy in WREG | |
| 880 andlw 0x0F ; keep only the tens | |
| 881 rlncf WREG, W ; WREG = 2 * tens | |
| 623 | 882 subwf isr_lo, F ; 16 * tens + ones - 2*tens |
| 883 subwf isr_lo, F ; 14 * tens + ones - 2*tens | |
| 884 subwf isr_lo, W ; 12 * tens + ones - 2*tens | |
| 634 | 885 return ; done |
| 0 | 886 |
| 887 | |
| 634 | 888 ;----------------------------------------------------------------------------- |
| 889 ; Check Buttons | |
| 623 | 890 ; |
| 582 | 891 isr_switch_right: |
| 640 | 892 bcf INTCON,INT0IE ; disable external interrupt 0 |
| 893 | |
| 894 btfsc button_hold_down_allowed,A ; ignore for mechanical push buttons | |
| 895 bra isr_switch_right2 | |
| 896 btfsc T4CON,TMR4ON ; Timer4 running? | |
| 897 bra timer4_restart ; Yes, restart | |
| 898 isr_switch_right2: | |
| 899 | |
| 582 | 900 btfss flip_screen ; 180° flipped? |
| 634 | 901 bsf switch_right ; NO - set flag for right button |
| 582 | 902 btfsc flip_screen ; 180° flipped? |
| 634 | 903 bsf switch_left ; YES - set flag for left button |
| 904 bra isr_switch_common ; continue with common part | |
| 0 | 905 |
| 582 | 906 isr_switch_left: |
| 640 | 907 bcf INTCON3,INT1IE ; disable external interrupt 1 |
| 908 | |
| 909 btfsc button_hold_down_allowed,A ; ignore for mechanical push buttons | |
| 910 bra isr_switch_left2 | |
| 911 btfsc T4CON,TMR4ON ; Timer4 running? | |
| 912 bra timer4_restart ; Yes, restart | |
| 913 isr_switch_left2: | |
| 914 | |
| 582 | 915 btfss flip_screen ; 180° flipped? |
| 634 | 916 bsf switch_left ; NO - set flag for left button |
| 582 | 917 btfsc flip_screen ; 180° flipped? |
| 634 | 918 bsf switch_right ; YES - set flag for right button |
| 919 ;bra isr_switch_common ; continue with common part | |
| 623 | 920 |
| 0 | 921 isr_switch_common: |
| 640 | 922 btfss button_hold_down_allowed,A ; ignore for mechanical push buttons |
| 923 bsf T4CON,TMR4ON ; Start timer 4 | |
| 924 | |
| 634 | 925 btfsc tmr5_preemtion_allowed ; timer 5 preemption allowed? |
| 926 bsf PIR5,TMR5IF ; YES - preempt timer 5 | |
| 927 movlw TMR1H_VALUE_FIRST ; load timer 1 (in steps of 7.8125 ms) | |
| 623 | 928 movwf TMR1H ; ... |
| 634 | 929 clrf TMR1L ; ... |
| 604 | 930 bsf T1CON,TMR1ON ; start timer 1 |
| 640 | 931 bcf INTCON3,INT1IF ; clear ext. int 1 request |
| 932 bcf INTCON,INT0IF ; clear ext. int 0 request | |
| 634 | 933 return ; done |
| 0 | 934 |
| 623 | 935 |
| 634 | 936 ;----------------------------------------------------------------------------- |
| 937 ; Button hold-down Interrupt | |
| 623 | 938 ; |
| 0 | 939 timer1int: |
| 634 | 940 bcf PIR1,TMR1IF ; clear timer 1 IRQ request |
| 640 | 941 bcf INTCON,INT0IF ; clear ext. int 0 request |
| 942 bcf INTCON3,INT1IF ; clear ext. int 1 request | |
| 634 | 943 |
| 451 | 944 ; digital |
| 604 | 945 btfss switch_left1 ; left button hold-down? |
| 946 bra timer1int_left ; YES | |
| 947 btfss switch_right2 ; right button hold-down? | |
| 948 bra timer1int_right ; YES | |
| 582 | 949 |
| 623 | 950 ; analog |
| 604 | 951 btfsc analog_sw2_pressed ; left button hold-down? |
| 952 bra timer1int_left ; YES | |
| 953 btfsc analog_sw1_pressed ; right button hold-down? | |
| 954 bra timer1int_right ; YES | |
| 582 | 955 |
| 634 | 956 ; no button hold-down, stop timer 1 |
| 604 | 957 bcf T1CON,TMR1ON ; stop timer 1 |
| 634 | 958 bsf INTCON,INT0IE ; enable INT0 IRQ |
| 959 bsf INTCON3,INT1IE ; enable INT1 IRQ | |
| 451 | 960 return |
| 0 | 961 |
| 962 timer1int_left: | |
| 582 | 963 btfss flip_screen ; 180° flipped? |
| 634 | 964 bsf switch_left ; set flag for left button |
| 582 | 965 btfsc flip_screen ; 180° flipped? |
| 634 | 966 bsf switch_right ; set flag for right button |
| 604 | 967 bra timer1int_common ; continue |
| 623 | 968 |
| 0 | 969 timer1int_right: |
| 582 | 970 btfss flip_screen ; 180° flipped? |
| 634 | 971 bsf switch_right ; set flag for right button |
| 582 | 972 btfsc flip_screen ; 180° flipped? |
| 634 | 973 bsf switch_left ; set flag for left button |
| 623 | 974 ;bra timer1int_common ; continue |
| 975 | |
| 634 | 976 timer1int_common: ; load timer 1 for next button press |
| 623 | 977 movlw TMR1H_VALUE_CONT ; default to surface mode value |
| 978 btfsc divemode ; in dive mode? | |
| 979 movlw TMR1H_VALUE_CONT_DIVE ; YES - overwrite with dive mode value | |
| 980 movwf TMR1H ; write value to timer, high byte | |
| 634 | 981 clrf TMR1L ; write value to timer, low byte (zero) |
| 982 return ; done (timer1 kept running) | |
| 0 | 983 |
| 623 | 984 |
| 634 | 985 ;----------------------------------------------------------------------------- |
| 986 ; Increment Surface Interval (counted in minutes and in seconds) | |
| 623 | 987 ; |
| 988 ; int_O_desaturation_time is only computed while in start, surface mode, | |
| 629 | 989 ; menue_tree or ghostwriter. So the ISR may clock surface_interval_mins |
| 634 | 990 ; past the actual surface interval time. But TFT_surf_cv_lastdive will |
| 629 | 991 ; check int_O_desaturation_time and in case int_O_desaturation_time is |
| 992 ; zero it will not show surface_interval_mins but surface_interval_secs instead. | |
| 993 ; Thus the glitch will remain invisible. | |
| 623 | 994 ; |
| 634 | 995 inc_surface_interval_secs: ; called every second when not in dive mode |
| 996 incf surface_interval_secs+0,F ; increment the lowest byte | |
| 997 clrf WREG ; clear WREG | |
| 998 addwfc surface_interval_secs+1,F ; add carry from byte before, if it did wrap-around | |
| 999 addwfc surface_interval_secs+2,F ; add carry from byte before, if it did wrap-around | |
| 1000 addwfc surface_interval_secs+3,F ; add carry from byte before, if it did wrap-around | |
| 1001 return ; done | |
| 629 | 1002 |
| 634 | 1003 inc_surface_interval_mins: ; called every minute when not in dive mode |
| 1004 movff int_O_desaturation_time+0,isr_lo ; get desaturation time, low byte | |
| 1005 movff int_O_desaturation_time+1,WREG ; get desaturation time, high byte | |
| 1006 iorwf isr_lo,W ; inclusive-or low & high byte, desaturation time = 0 ? | |
| 1007 bz clr_surface_interval_mins ; YES - reset surface interval minutes counter | |
| 1008 INCI surface_interval_mins ; NO - increment surface interval | |
| 1009 return ; - done | |
| 629 | 1010 |
| 631 | 1011 rst_surface_interval: |
| 629 | 1012 bcf reset_surface_interval ; reset request flag |
| 631 | 1013 ; reset the surface interval counted in seconds |
| 629 | 1014 clrf surface_interval_secs+0 ; reset surface interval (seconds), lowest byte |
| 1015 clrf surface_interval_secs+1 ; ... | |
| 1016 clrf surface_interval_secs+2 ; ... | |
| 1017 clrf surface_interval_secs+3 ; reset surface interval (seconds), highest byte | |
| 631 | 1018 ; reset the surface interval counted in minutes |
| 629 | 1019 movff opt_diveTimeout,surface_interval_mins+0 ; set surface interval (minutes), low byte, to dive timeout offset |
| 1020 clrf surface_interval_mins+1 ; reset surface interval (minutes), high byte | |
| 631 | 1021 return ; done |
| 629 | 1022 |
| 631 | 1023 clr_surface_interval_mins: |
| 1024 clrf surface_interval_mins+0 ; reset surface interval (minutes), low byte | |
| 1025 clrf surface_interval_mins+1 ; reset surface interval (minutes), high byte | |
| 629 | 1026 return ; done |
| 1027 | |
| 634 | 1028 ;----------------------------------------------------------------------------- |
| 0 | 1029 |
| 582 | 1030 END |