Mercurial > public > hwos_code
annotate src/isr.asm @ 174:932e91074bdb
CHANGE: Clarify Travel Gases with "---" as change depth
CHANGE: Enable "Change Depth" Menu only for deco gases
| author | heinrichsweikamp |
|---|---|
| date | Sun, 05 Oct 2014 15:36:17 +0200 |
| parents | df449e5b1c81 |
| children | 3fdafedc24af |
| rev | line source |
|---|---|
| 0 | 1 ;============================================================================= |
| 2 ; | |
| 3 ; File isr.asm | |
| 4 ; | |
| 5 ; INTERUPT subroutines | |
| 6 ; | |
| 7 ; Copyright (c) 2011, JD Gascuel, HeinrichsWeikamp, all right reserved. | |
| 8 ;============================================================================= | |
| 9 ; HISTORY | |
| 10 ; 2011-05-24 : [jDG] Cleanups from initial Matthias code. | |
| 11 | |
| 12 #include "ostc3.inc" | |
| 13 #include "shared_definitions.h" ; Mailbox from/to p2_deco.c | |
| 14 #include "ms5541.inc" | |
| 15 #include "adc_lightsensor.inc" | |
| 16 | |
| 17 ;============================================================================= | |
| 18 | |
| 19 extern start | |
| 20 | |
| 21 isr_high CODE 0x0008 ;High Priority Interrups | |
| 22 bra HighInt | |
| 23 nop | |
| 24 nop | |
| 25 nop | |
| 26 nop | |
| 27 nop | |
| 28 nop | |
| 29 bra HighInt | |
| 30 | |
| 31 isr_low CODE 0x00018 ;Low Priority Interrups | |
| 32 ; *** low priority interrupts not used | |
| 33 retfie FAST ; Restores BSR, STATUS and WREG | |
| 34 | |
| 35 HighInt: | |
| 36 movff PRODL,isr_prod+0 | |
| 37 movff PRODH,isr_prod+1 | |
| 38 | |
| 39 ; Buttons | |
| 40 btfsc PIR1,TMR1IF ; Timer1 INT (Button hold-down Timer) | |
| 41 rcall timer1int | |
| 42 btfsc INTCON,INT0IF ; Buttons | |
| 43 rcall isr_switch_right | |
| 44 btfsc INTCON3,INT1IF ; Buttons | |
| 45 rcall isr_switch_left | |
| 46 | |
| 47 ; IR-Link | |
| 113 | 48 btfsc PIR3,RC2IF ; UART2 |
| 49 rcall isr_uart2 ; IR-Link | |
| 0 | 50 btfsc PIR2,TMR3IF ; Timer 3 |
| 51 rcall isr_timer3 ; IR-Link Timeout | |
| 113 | 52 |
| 53 ; Pressure sensor and others | |
| 54 btfsc PIR5,TMR7IF ; Timer 7 | |
| 55 rcall isr_tmr7 ; Every 62,5ms | |
| 56 | |
| 0 | 57 ; RTCC |
| 58 btfsc PIR3,RTCCIF ; Real-time-clock interrupt | |
| 59 rcall isr_rtcc ; May return in bank common! | |
| 60 | |
| 61 movff isr_prod+1,PRODH | |
| 62 movff isr_prod+0,PRODL | |
| 63 retfie FAST ; Restores BSR, STATUS and WREG | |
| 64 | |
| 65 ;============================================================================= | |
| 66 | |
| 67 isr_uart2: ; IR-Link | |
| 68 banksel RCREG2 | |
| 69 movf RCREG2,W | |
| 70 bcf RCSTA2,CREN ; Clear receiver status | |
| 71 bsf RCSTA2,CREN | |
| 72 banksel isr_backup | |
| 73 incf ir_counter,F ; Increase counter | |
| 74 movff ir_counter,isr1_temp ; Copy | |
| 75 dcfsnz isr1_temp,F | |
| 76 movwf ir_buffer+.0 | |
| 77 dcfsnz isr1_temp,F | |
| 78 movwf ir_buffer+.1 | |
| 79 dcfsnz isr1_temp,F | |
| 80 movwf ir_buffer+.2 | |
| 81 dcfsnz isr1_temp,F | |
| 82 movwf ir_buffer+.3 | |
| 83 dcfsnz isr1_temp,F | |
| 84 movwf ir_buffer+.4 | |
| 85 dcfsnz isr1_temp,F | |
| 86 movwf ir_buffer+.5 | |
| 87 dcfsnz isr1_temp,F | |
| 88 movwf ir_buffer+.6 | |
| 89 dcfsnz isr1_temp,F | |
| 90 movwf ir_buffer+.7 | |
| 91 dcfsnz isr1_temp,F | |
| 92 movwf ir_buffer+.8 | |
| 93 dcfsnz isr1_temp,F | |
| 94 movwf ir_buffer+.9 | |
| 95 dcfsnz isr1_temp,F | |
| 96 movwf ir_buffer+.10 | |
| 97 dcfsnz isr1_temp,F | |
| 98 movwf ir_buffer+.11 | |
| 99 dcfsnz isr1_temp,F | |
| 100 movwf ir_buffer+.12 | |
| 101 dcfsnz isr1_temp,F | |
| 102 movwf ir_buffer+.13 | |
| 103 dcfsnz isr1_temp,F | |
| 104 movwf ir_buffer+.14 | |
| 105 dcfsnz isr1_temp,F | |
| 106 movwf ir_buffer+.15 | |
| 113 | 107 dcfsnz isr1_temp,F |
| 108 movwf ir_buffer+.16 | |
| 109 dcfsnz isr1_temp,F | |
| 110 movwf ir_buffer+.17 | |
| 111 | |
| 0 | 112 clrf TMR3L ; Preload timer |
| 113 movlw .253 | |
| 114 movwf TMR3H | |
| 115 bsf T3CON,TMR3ON ; (Re)Start Timeout counter | |
| 116 return | |
| 117 | |
| 118 isr_timer3: ; IR-Link Timeout | |
| 119 bcf T3CON,TMR3ON ; Stop Timer3 | |
| 120 banksel isr_backup ; Select Bank0 for ISR data. | |
| 121 movlw .15 | |
| 122 cpfseq ir_counter ; Got exact 15bytes? | |
| 123 bra isr_timer3_1 ; No, test for 16bytes | |
| 113 | 124 bra isr_timer3_ir ; Got 15 bytes, compute local checksum |
| 0 | 125 isr_timer3_1: |
| 126 movlw .16 | |
| 127 cpfseq ir_counter ; Got exact 16bytes? | |
| 113 | 128 bra isr_timer3_2 ; No, test for 17bytes |
| 0 | 129 tstfsz ir_buffer+.15 ; Last byte=0x00 |
| 130 bra isr_timer3_exit ; No, exit | |
| 113 | 131 bra isr_timer3_ir ; Got 16 bytes, compute local checksum |
| 132 isr_timer3_2: | |
| 133 movlw .17 | |
| 134 cpfseq ir_counter ; Got exact 17bytes? | |
| 135 bra isr_timer3_exit ; No, exit | |
| 136 bra isr_timer3_s8 ; S8 data | |
| 0 | 137 |
| 113 | 138 isr_timer3_ir: ; IR input |
| 0 | 139 movff ir_buffer+.0,PRODL |
| 140 clrf PRODH | |
| 141 movf ir_buffer+.1,W | |
| 142 rcall isr_timer3_checksum | |
| 143 movf ir_buffer+.2,W | |
| 144 rcall isr_timer3_checksum | |
| 145 movf ir_buffer+.3,W | |
| 146 rcall isr_timer3_checksum | |
| 147 movf ir_buffer+.4,W | |
| 148 rcall isr_timer3_checksum | |
| 149 movf ir_buffer+.5,W | |
| 150 rcall isr_timer3_checksum | |
| 151 movf ir_buffer+.6,W | |
| 152 rcall isr_timer3_checksum | |
| 153 movf ir_buffer+.7,W | |
| 154 rcall isr_timer3_checksum | |
| 155 movf ir_buffer+.8,W | |
| 156 rcall isr_timer3_checksum | |
| 157 movf ir_buffer+.9,W | |
| 158 rcall isr_timer3_checksum | |
| 159 movf ir_buffer+.10,W | |
| 160 rcall isr_timer3_checksum | |
| 161 movf ir_buffer+.11,W | |
| 162 rcall isr_timer3_checksum | |
| 163 movf ir_buffer+.12,W | |
| 164 rcall isr_timer3_checksum | |
| 165 | |
| 166 ; Compare checksum | |
| 167 movf ir_buffer+.13,W | |
| 168 cpfseq PRODL ; Checksum ok? | |
| 169 bra isr_timer3_exit ; No, exit | |
| 170 movf ir_buffer+.14,W | |
| 171 cpfseq PRODH ; Checksum ok? | |
| 172 bra isr_timer3_exit ; No, exit | |
| 173 | |
| 174 ; Checksum OK, copy results | |
| 175 movff ir_buffer+.1,hud_status_byte | |
| 176 movff ir_buffer+.2,o2_mv_sensor1+0 | |
| 177 movff ir_buffer+.3,o2_mv_sensor1+1 | |
| 178 movff ir_buffer+.4,o2_mv_sensor2+0 | |
| 179 movff ir_buffer+.5,o2_mv_sensor2+1 | |
| 180 movff ir_buffer+.6,o2_mv_sensor3+0 | |
| 181 movff ir_buffer+.7,o2_mv_sensor3+1 | |
| 182 movff ir_buffer+.8,o2_ppo2_sensor1 | |
| 183 movff ir_buffer+.9,o2_ppo2_sensor2 | |
| 184 movff ir_buffer+.10,o2_ppo2_sensor3 | |
| 185 movff ir_buffer+.11,hud_battery_mv+0 | |
| 186 movff ir_buffer+.12,hud_battery_mv+1 | |
| 187 | |
| 188 movlw ir_timeout_value ; multiples of 62,5ms | |
| 189 movwf ir_timeout ; Reload timeout | |
| 190 | |
| 191 isr_timer3_exit: | |
| 192 clrf ir_counter ; Clear pointer | |
| 193 bcf PIR2,TMR3IF ; Clear flag | |
| 194 return | |
| 195 | |
| 196 isr_timer3_checksum: | |
| 197 addwf PRODL,F | |
| 198 movlw .0 | |
| 199 addwfc PRODH,F | |
| 200 return | |
| 201 | |
| 113 | 202 isr_timer3_s8: ; IR input |
| 203 movff ir_buffer+.0,PRODL | |
| 204 clrf PRODH | |
| 205 movf ir_buffer+.1,W | |
| 206 rcall isr_timer3_checksum | |
| 207 movf ir_buffer+.2,W | |
| 208 rcall isr_timer3_checksum | |
| 209 movf ir_buffer+.3,W | |
| 210 rcall isr_timer3_checksum | |
| 211 movf ir_buffer+.4,W | |
| 212 rcall isr_timer3_checksum | |
| 213 movf ir_buffer+.5,W | |
| 214 rcall isr_timer3_checksum | |
| 215 movf ir_buffer+.6,W | |
| 216 rcall isr_timer3_checksum | |
| 217 movf ir_buffer+.7,W | |
| 218 rcall isr_timer3_checksum | |
| 219 movf ir_buffer+.8,W | |
| 220 rcall isr_timer3_checksum | |
| 221 movf ir_buffer+.9,W | |
| 222 rcall isr_timer3_checksum | |
| 223 movf ir_buffer+.10,W | |
| 224 rcall isr_timer3_checksum | |
| 225 movf ir_buffer+.11,W | |
| 226 rcall isr_timer3_checksum | |
| 227 movf ir_buffer+.12,W | |
| 228 rcall isr_timer3_checksum | |
| 229 movf ir_buffer+.13,W | |
| 230 rcall isr_timer3_checksum | |
| 231 movf ir_buffer+.14,W | |
| 232 rcall isr_timer3_checksum | |
| 233 | |
| 234 ; Compare checksum | |
| 235 movf ir_buffer+.15,W | |
| 236 cpfseq PRODL ; Checksum ok? | |
| 237 bra isr_timer3_exit ; No, exit | |
| 238 movf ir_buffer+.16,W | |
| 239 cpfseq PRODH ; Checksum ok? | |
| 240 bra isr_timer3_exit ; No, exit | |
| 241 | |
| 242 ; Checksum OK, copy results | |
| 243 movff ir_buffer+.3,hud_status_byte | |
| 244 movff ir_buffer+.13,hud_battery_mv+0 | |
| 245 movff ir_buffer+.14,hud_battery_mv+1 | |
| 246 | |
| 247 banksel common | |
| 248 bsf new_s8_data_available ; set flag | |
| 249 banksel ir_timeout | |
| 250 | |
| 251 movlw ir_timeout_value ; multiples of 62,5ms | |
| 252 movwf ir_timeout ; Reload timeout | |
| 253 bra isr_timer3_exit ; Exit | |
| 254 | |
| 255 | |
| 0 | 256 ;============================================================================= |
| 257 | |
| 258 isr_tmr7: ; each 62,5ms | |
| 259 bcf PIR5,TMR7IF ; clear flag | |
| 260 banksel 0xF16 ; Addresses, F16h through F5Fh, are also used by SFRs, but are not part of the Access RAM. | |
| 261 movlw .248 | |
| 262 movwf TMR7H ; -> Rollover after 2048 cycles -> 62,5ms | |
| 263 | |
| 264 banksel isr_backup | |
| 265 movf max_CCPR1L,W ; Dimm value | |
| 266 cpfseq CCPR1L ; = current PWM value? | |
| 267 rcall isr_dimm_tft ; No, adjust until max_CCPR1L=CCPR1L ! | |
| 268 | |
| 269 banksel isr_backup | |
| 270 decfsz ir_timeout,F ; IR Data still valid? | |
| 271 bra isr_tmr7_2 ; Yes, continue | |
| 272 ; timeout, clear IR-Data | |
| 273 | |
| 274 movlw ir_timeout_value ; multiples of 62,5ms | |
| 275 movwf ir_timeout ; Reload timeout | |
| 276 | |
| 277 banksel common | |
| 113 | 278 btfss c3_hardware |
| 279 bra isr_tmr7_1a ; Always with normal ostc3 hardware | |
| 280 btfss s8_digital | |
| 281 bra isr_tmr7_2 ; only when digital | |
| 282 isr_tmr7_1a: | |
| 0 | 283 clrf o2_mv_sensor1+0 |
| 284 clrf o2_mv_sensor1+1 | |
| 285 clrf o2_mv_sensor2+0 | |
| 286 clrf o2_mv_sensor2+1 | |
| 287 clrf o2_mv_sensor3+0 | |
| 288 clrf o2_mv_sensor3+1 | |
| 289 clrf hud_battery_mv+0 | |
| 290 clrf hud_battery_mv+1 | |
| 291 clrf hud_status_byte | |
| 292 clrf o2_ppo2_sensor1 | |
| 293 clrf o2_ppo2_sensor2 | |
| 294 clrf o2_ppo2_sensor3 | |
| 295 | |
| 296 isr_tmr7_2: | |
| 297 banksel common | |
| 298 btfss no_sensor_int ; No sensor interrupt (because it's addressed during sleep) | |
| 299 bra isr_sensor_state2 ; No, continue | |
| 300 banksel isr_backup ; Back to Bank0 ISR data | |
| 301 return | |
| 302 | |
| 303 isr_set_speed_to_normal: | |
| 304 ; Set Speed to normal | |
| 305 movlw b'01110010' | |
| 306 movwf OSCCON ; 16MHz INTOSC | |
| 307 movlw b'00000000' | |
| 308 movwf OSCTUNE ; 4x PLL Disable (Bit6) - only works with 8 or 16MHz (=32 or 64MHz) | |
| 309 movlw b'00001101' ; 1:2 Postscaler, 1:4 Prescaler, Timer 2 start -> 1960Hz (no-flicker) | |
| 310 movwf T2CON | |
| 311 btfss OSCCON,HFIOFS | |
| 312 bra $-2 ; Wait until clock is stable | |
| 313 return | |
| 314 | |
| 315 isr_sensor_state2: | |
| 316 banksel common | |
| 317 movff sensor_state_counter,WREG | |
| 318 btfss WREG,0 ; every 1/4 second | |
| 319 bsf quarter_second_update ; Set flag | |
| 320 movlw d'2' | |
| 321 cpfseq speed_setting ; Set to normal in case it's not already in normal speed mode | |
| 322 rcall isr_set_speed_to_normal | |
| 323 banksel isr_backup ; Back to Bank0 ISR data | |
| 324 | |
| 325 incf sensor_state_counter,F ; counts to eight for state maschine | |
| 326 | |
| 327 ; State 1: Clear flags and average registers, get temperature (51us) and start pressure integration (73,5us) | |
| 328 ; State 2: Get pressure (51us), start temperature integration (73,5us) and calculate temperature compensated pressure (233us) | |
| 329 ; State 3: Get temperature (51us) and start pressure integration (73,5us) | |
| 330 ; State 4: Get pressure (51us), start temperature integration (73,5us) and calculate temperature compensated pressure (233us) | |
| 331 ; State 5: Get temperature (51us) and start pressure integration (73,5us) | |
| 332 ; State 6: Get pressure (51us), start temperature integration (73,5us) and calculate temperature compensated pressure (233us) | |
| 333 ; State 7: Get temperature (51us) and start pressure integration (73,5us) | |
| 334 ; State 8: Get pressure (51us), start temperature integration (73,5us), calculate temperature compensated pressure (233us) and build average for half-second update of tempperature and pressure | |
| 335 | |
| 336 movff sensor_state_counter,WREG ; WREG used as temp here... | |
| 337 dcfsnz WREG,F | |
| 338 bra sensor_int_state1_plus_restart ; Do State 1 | |
| 339 dcfsnz WREG,F | |
| 340 bra sensor_int_state2 ; Do State 2 | |
| 341 dcfsnz WREG,F | |
| 342 bra sensor_int_state1 ; Do State 3 | |
| 343 dcfsnz WREG,F | |
| 344 bra sensor_int_state2 ; Do State 4 | |
| 345 dcfsnz WREG,F | |
| 346 bra sensor_int_state1 ; Do State 5 | |
| 347 dcfsnz WREG,F | |
| 348 bra sensor_int_state2 ; Do State 6 | |
| 349 dcfsnz WREG,F | |
| 350 bra sensor_int_state1 ; Do State 7 | |
| 351 ; bra sensor_int2_plus_average ; Do State 8 | |
| 352 ;sensor_int2_plus_average: | |
| 353 ; First, do state2: | |
| 354 call get_pressure_value ; State2: Get pressure (51us) | |
| 355 call get_temperature_start ; and start temperature integration (73,5us) | |
| 356 call calculate_compensation ; calculate temperature compensated pressure (27us) | |
| 357 ; Build average | |
| 358 bcf STATUS,C ; clear carry bit. | |
| 359 rrcf amb_pressure_avg+1 ; amb_pressure sum / 2 | |
| 360 rrcf amb_pressure_avg+0 | |
| 361 bcf STATUS,C ; clear carry bit, twice. | |
| 362 rrcf amb_pressure_avg+1 ; amb_pressure sum / 4 | |
| 363 rrcf amb_pressure_avg+0 | |
| 364 | |
| 365 ; ; Even more averaging | |
| 366 ; movf amb_pressure_avg+0,W | |
| 367 ; addwf amb_pressure+0 | |
| 368 ; movf amb_pressure_avg+1,W | |
| 369 ; addwfc amb_pressure+1 | |
| 370 ; bcf STATUS,C ; clear carry bit | |
| 371 ; rrcf amb_pressure+1 ; amb_pressure sum / 2 | |
| 372 ; rrcf amb_pressure+0 | |
| 373 | |
| 374 movff amb_pressure_avg+1,amb_pressure+1 ; copy into actual register | |
| 375 movff amb_pressure_avg+0,amb_pressure+0 | |
| 376 | |
| 377 bcf STATUS,C | |
| 378 btfsc temperature_avg+1,7 ; Copy sign bit to carry | |
| 379 bsf STATUS,C | |
| 380 rrcf temperature_avg+1 ; Signed temperature /2 | |
| 381 rrcf temperature_avg+0 | |
| 382 bcf STATUS,C | |
| 383 btfsc temperature_avg+1,7 ; Copy sign bit to carry | |
| 384 bsf STATUS,C | |
| 385 rrcf temperature_avg+1 ; Signed temperature /4 | |
| 386 rrcf temperature_avg+0 | |
| 387 | |
| 388 movff temperature_avg+1,temperature+1 ; copy into actual register | |
| 389 movff temperature_avg+0,temperature+0 | |
| 390 | |
| 391 banksel common ; flag1 is in Bank1 | |
| 392 bcf temp_changed ; Clear flag for temperature update | |
| 393 bcf pressure_refresh ; Clear flag for pressure update | |
| 394 banksel isr_backup ; Back to Bank0 ISR data | |
| 395 | |
| 396 ; Temp changed? | |
| 397 movf temperature+0,W | |
| 398 cpfseq last_temperature+0 | |
| 399 bra isr_sensor_state2_2 ; Yes | |
| 400 movf temperature+1,W | |
| 401 cpfseq last_temperature+1 | |
| 402 bra isr_sensor_state2_2 ; Yes | |
| 403 | |
| 404 bra isr_sensor_state2_3 ; no change | |
| 405 | |
| 406 isr_sensor_state2_2: | |
| 407 banksel common ; flag1 is in Bank1 | |
| 408 bsf temp_changed ; Yes | |
| 409 banksel isr_backup ; Back to Bank0 ISR data | |
| 410 isr_sensor_state2_3: | |
| 411 movff temperature+0,last_temperature+0 ; Copy for compare | |
| 412 movff temperature+1,last_temperature+1 | |
| 413 | |
| 414 movf amb_pressure+0,W | |
| 415 cpfseq last_pressure+0 | |
| 416 bra isr_sensor_state2_4 ; Yes | |
| 417 movf amb_pressure+1,W | |
| 418 cpfseq last_pressure+1 | |
| 419 bra isr_sensor_state2_4 ; Yes | |
| 420 | |
| 421 bra isr_sensor_state2_5 ; No change | |
| 422 isr_sensor_state2_4: | |
| 423 banksel common ; flag1 is in Bank1 | |
| 424 bsf pressure_refresh ; Yes | |
| 425 banksel isr_backup ; Back to Bank0 ISR data | |
| 426 isr_sensor_state2_5: | |
| 427 movff amb_pressure+0,last_pressure+0 ; Copy for compare | |
| 428 movff amb_pressure+1,last_pressure+1 | |
| 429 | |
| 430 clrf sensor_state_counter ; Then reset State counter | |
| 431 btfss simulatormode_active ; are we in simulator mode? | |
| 432 bra comp_air_pressure ; no | |
| 433 comp_air_pressure0: | |
| 434 movlw LOW d'1000' ; yes, so simulate 1000mbar surface pressure | |
| 435 movwf last_surfpressure+0 | |
| 436 movlw HIGH d'1000' | |
| 437 movwf last_surfpressure+1 | |
| 438 ; Always set pressure_refresh flag in simulator mode | |
| 439 banksel common ; flag1 is in Bank1 | |
| 440 bsf pressure_refresh ; Yes | |
| 441 banksel isr_backup ; Back to Bank0 ISR data | |
| 442 | |
| 443 comp_air_pressure: | |
| 444 movf last_surfpressure+0,W ; compensate airpressure | |
| 445 subwf amb_pressure+0,W | |
| 446 movwf rel_pressure+0 ; rel_pressure stores depth! | |
| 447 | |
| 448 movf last_surfpressure+1,W | |
| 449 subwfb amb_pressure+1,W | |
| 450 movwf rel_pressure+1 | |
| 451 btfss STATUS,N ; result is below zero? | |
| 452 bra sensor_int_state_exit | |
| 453 clrf rel_pressure+0 ; Yes, do not display negative depths | |
| 454 clrf rel_pressure+1 ; e.g. when surface air pressure dropped during the dive | |
| 455 bra sensor_int_state_exit | |
| 456 | |
| 457 sensor_int_state1_plus_restart: | |
| 458 clrf amb_pressure_avg+0 ; pressure average registers | |
| 459 clrf amb_pressure_avg+1 | |
| 460 clrf temperature_avg+0 | |
| 461 clrf temperature_avg+1 | |
| 462 | |
| 463 sensor_int_state1: | |
| 464 call get_temperature_value ; State 1: Get temperature | |
| 465 call get_pressure_start ; and start pressure integration. | |
| 466 bra sensor_int_state_exit | |
| 467 | |
| 468 sensor_int_state2: | |
| 469 call get_pressure_value ; State2: Get pressure (51us) | |
| 470 call get_temperature_start ; and start temperature integration (73,5us) | |
| 471 call calculate_compensation ; calculate temperature compensated pressure (233us) | |
| 472 ; bra sensor_int_state_exit | |
| 473 sensor_int_state_exit: | |
| 474 rcall isr_restore_clock ; Restore clock | |
| 475 return | |
| 476 ;============================================================================= | |
| 477 | |
| 478 isr_dimm_tft: ; Adjust until max_CCPR1L=CCPR1L ! | |
| 479 banksel common | |
| 480 btfsc tft_is_dimming ; Ignore while dimming | |
| 481 return | |
| 482 banksel isr_backup | |
| 483 movf max_CCPR1L,W | |
| 484 cpfsgt CCPR1L ; CCPR1L>max_CCPR1L? | |
| 485 bra isr_dimm_tft2 ; No, dimm up | |
| 486 ; dimm down | |
| 487 decf CCPR1L,F ; -1 | |
| 488 return | |
| 489 isr_dimm_tft2: | |
| 490 movf max_CCPR1L,W | |
|
31
53a09c1b7410
BUGFIX: alternating brightness at very low ambient light
heinrichsweikamp
parents:
30
diff
changeset
|
491 sublw ambient_light_min_eco |
|
53a09c1b7410
BUGFIX: alternating brightness at very low ambient light
heinrichsweikamp
parents:
30
diff
changeset
|
492 cpfsgt CCPR1L ; CCPR1L>max_CCPR1L-ambient_light_min_eco? |
| 0 | 493 bra isr_dimm_tft3 ; No, dimm up slow |
| 494 ; dimm up faster | |
| 495 movlw .5 | |
| 496 addwf CCPR1L,F | |
| 497 isr_dimm_tft3: | |
| 498 incf CCPR1L,F ; +1 | |
| 499 return | |
| 500 | |
| 501 | |
| 502 isr_rtcc: ; each second | |
| 503 bcf PIR3,RTCCIF ; clear flag | |
| 504 banksel 0xF16 ; Addresses, F16h through F5Fh, are also used by SFRs, but are not part of the Access RAM. | |
| 505 bsf RTCCFG,RTCPTR1 | |
| 506 bsf RTCCFG,RTCPTR0 ; year | |
| 507 movff RTCVALL,year ; format is BCD! | |
| 508 movff RTCVALH,day ; dummy read | |
| 509 movff RTCVALL,day ; format is BCD! | |
| 510 movff RTCVALH,month ; format is BCD! | |
| 511 movff RTCVALL,hours ; format is BCD! | |
| 512 movff RTCVALH,secs ; format is BCD! | |
| 513 movff RTCVALL,secs ; format is BCD! | |
| 514 movff RTCVALH,mins ; format is BCD! | |
| 515 banksel isr_backup ; Back to Bank0 ISR data | |
| 516 | |
| 517 ; Convert BCD to DEC and set registers | |
| 518 movff mins, isr1_temp | |
| 519 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 520 movff WREG,mins | |
| 521 movff secs, isr1_temp | |
| 522 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 523 movff WREG,secs | |
| 524 movff hours, isr1_temp | |
| 525 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 526 movff WREG,hours | |
| 527 movff month, isr1_temp | |
| 528 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 529 movff WREG,month | |
| 530 movff day, isr1_temp | |
| 531 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 532 movff WREG,day | |
| 533 movff year, isr1_temp | |
| 534 rcall isr_rtcc_convert ; Converts to dec with result in WREG | |
| 535 movff WREG,year | |
| 536 | |
| 537 ; Place once/second tasks for ISR here (Be sure of the right bank!) | |
| 538 banksel common ; flag1 is in Bank1 | |
| 539 btfss sleepmode ; in Sleepmode? | |
| 540 call get_ambient_level ; No, get ambient light level and set max_CCPR1L | |
| 541 | |
| 542 rcall isr_battery_gauge ; Add amount of battery consumption to battery_gauge:6 | |
| 543 | |
| 544 banksel common ; flag1 is in Bank1 | |
| 545 bsf onesecupdate ; A new second has begun | |
| 546 btfsc divemode ; in divemode? | |
| 547 rcall isr_divemode_1sec ; Yes, do some divemode stuff in bank common | |
| 548 | |
| 549 tstfsz secs ; Secs == 0 ? | |
| 550 return ; No, Done. | |
| 551 | |
| 552 bsf oneminupdate ; A new minute has begun | |
| 553 | |
| 554 btfss divemode ; In Divemode? | |
| 555 rcall check_nofly_desat_time ; No, so reduce NoFly and Desat and increase interval | |
| 556 | |
| 557 ; Check if a new hour has just begun | |
| 558 tstfsz mins ; mins=0? | |
| 559 bra isr_rtcc2 ; No | |
| 560 bsf onehourupdate ; Yes, set flag | |
| 561 | |
| 562 isr_rtcc2: | |
| 563 banksel isr_backup ; Back to Bank0 ISR data | |
| 564 return ; Done. | |
| 565 | |
| 566 isr_battery_gauge: | |
| 567 banksel isr_backup ; Bank0 ISR data | |
| 568 movlw current_sleepmode ; 100µA/3600 -> nAs (Sleepmode current) | |
| 569 movwf isr1_temp ; Store value (low byte) | |
| 570 clrf isr2_temp ; High byte | |
| 571 | |
| 572 banksel common ; flag1 is in Bank1 | |
| 573 btfss sleepmode ; in Sleepmode? | |
| 574 rcall isr_battery_gauge2 ; No, compute current consumtion value into isr1_temp and isr2_temp | |
| 575 | |
| 576 banksel isr_backup ; Bank0 ISR data | |
| 577 movf isr1_temp,W ; 48Bit add of isr1_temp and isr2_temp into battery_gauge:6 | |
| 578 addwf battery_gauge+0,F | |
| 579 movf isr2_temp,W | |
| 580 addwfc battery_gauge+1,F | |
| 581 movlw .0 | |
| 582 addwfc battery_gauge+2,F | |
| 583 addwfc battery_gauge+3,F | |
| 584 addwfc battery_gauge+4,F | |
| 585 addwfc battery_gauge+5,F | |
| 586 return | |
| 587 | |
| 588 isr_battery_gauge2: | |
| 589 ; set consumtion rate in nAs for an one second interval | |
| 590 ; Example: | |
| 591 ; movlw LOW .55556 ; 0,2A/3600*1e9s = nAs | |
| 592 ; movwf isr1_temp ; Low byte | |
| 593 ; movlw HIGH .55556 ; 0,2A/3600*1e9s = nAs | |
| 594 ; movwf isr2_temp ; High byte | |
| 595 | |
| 596 ; Current consumption for LED backlight is 47*CCPR1L+272 | |
| 597 movf CCPR1L,W | |
| 598 mullw current_backlight_multi | |
| 599 movlw LOW current_backlight_offset | |
| 600 addwf PRODL,F | |
| 601 movlw HIGH current_backlight_offset | |
| 602 addwfc PRODH,F | |
| 603 movff PRODL,isr1_temp | |
| 604 movff PRODH,isr2_temp ; isr1_temp and isr2_temp hold value for backlight | |
| 605 | |
| 606 ; Add current for CPU and GPU | |
| 607 ; speed_setting=1: ECO (3,1mA -> 861nAs), =2: NORMAL (5,50mA -> 1528nAs) or =3: FASTEST (8,04mA -> 2233nAs) | |
| 608 movlw .1 | |
| 609 cpfseq speed_setting | |
| 610 bra isr_battery_gauge3 | |
| 611 banksel isr_backup ; Bank0 ISR data | |
| 612 movlw LOW current_speed_eco | |
| 613 addwf isr1_temp,F | |
| 614 movlw HIGH current_speed_eco | |
| 615 addwfc isr2_temp,F | |
| 616 bra isr_battery_gauge5 | |
| 617 isr_battery_gauge3: | |
| 618 movlw .2 | |
| 619 cpfseq speed_setting | |
| 620 bra isr_battery_gauge4 | |
| 621 banksel isr_backup ; Bank0 ISR data | |
| 622 movlw LOW current_speed_normal | |
| 623 addwf isr1_temp,F | |
| 624 movlw HIGH current_speed_normal | |
| 625 addwfc isr2_temp,F | |
| 626 bra isr_battery_gauge5 | |
| 627 isr_battery_gauge4: | |
| 628 ; movlw .3 | |
| 629 ; cpfseq speed_setting | |
| 630 ; bra isr_battery_gauge5 | |
| 631 banksel isr_backup ; Bank0 ISR data | |
| 632 movlw LOW current_speed_fastest | |
| 633 addwf isr1_temp,F | |
| 634 movlw HIGH current_speed_fastest | |
| 635 addwfc isr2_temp,F | |
| 636 isr_battery_gauge5: | |
| 637 ; Add current if IR reciever is on | |
| 638 btfss ir_power ; IR enabled? | |
| 639 bra isr_battery_gauge6 ; no | |
| 640 movlw LOW current_ir_reciever | |
| 641 addwf isr1_temp,F | |
| 642 movlw HIGH current_ir_reciever | |
| 643 addwfc isr2_temp,F | |
| 644 isr_battery_gauge6: | |
| 645 ; Add current for compass/accelerometer | |
| 646 btfss compass_enabled ; compass active? | |
| 647 bra isr_battery_gauge7 ; no | |
| 648 movlw LOW current_compass | |
| 649 addwf isr1_temp,F | |
| 650 movlw HIGH current_compass | |
| 651 addwfc isr2_temp,F | |
| 652 isr_battery_gauge7: | |
| 653 return | |
| 654 | |
| 655 isr_divemode_1sec: | |
| 656 incf samplesecs,F ; "samplingrate" diving seconds done | |
| 657 decf samplesecs_value,W ; holds "samplingrate" value (minus 1 into WREG) | |
| 658 cpfsgt samplesecs ; Done? | |
| 659 bra isr_divemode_1sec2 ; no | |
| 660 | |
| 661 clrf samplesecs ; clear counter... | |
| 662 bsf store_sample ; ...and set bit for profile storage | |
| 663 isr_divemode_1sec2: | |
| 664 ; Increase re-setable average depth divetime counter | |
| 665 incf average_divesecs+0,F ; increase stopwatch registers | |
| 666 btfsc STATUS,Z | |
| 667 incf average_divesecs+1,F ; increase stopwatch registers | |
| 668 ; Increase total divetime (Regardless of start_dive_threshold) | |
| 148 | 669 infsnz total_divetime_seconds+0,F |
| 670 incf total_divetime_seconds+1,F ; Total dive time (Regardless of start_dive_threshold) | |
| 0 | 671 |
| 672 btfss divemode2 ; displayed divetime is running? | |
| 673 return ; No (e.g. too shallow) | |
| 674 | |
| 675 ; increase divetime registers (Displayed dive time) | |
| 676 incf divesecs,F | |
| 677 movlw d'59' | |
| 678 cpfsgt divesecs | |
| 679 bra isr_divemode_1sec2a | |
| 680 | |
| 681 clrf divesecs | |
| 682 bsf realdive ; this bit is always set (again) if the dive is longer then one minute | |
| 148 | 683 infsnz divemins+0,F |
| 684 incf divemins+1,F ; increase divemins | |
| 0 | 685 |
| 686 isr_divemode_1sec2a: | |
| 687 btfss FLAG_apnoe_mode ; Are we in Apnoe mode? | |
| 688 return ; No | |
| 689 | |
| 690 incf apnoe_secs,F ; increase descent registers | |
| 691 movlw d'59' | |
| 692 cpfsgt apnoe_secs ; full minute? | |
| 693 return ; No | |
| 694 clrf apnoe_secs | |
| 695 incf apnoe_mins,F ; increase descent mins | |
| 696 return | |
| 697 | |
| 698 ;============================================================================= | |
| 699 ; BCD to Binary convertion. | |
| 700 ; Input: isr1_temp = Value in BCD | |
| 701 ; Output WREG = value in binary. | |
| 702 isr_rtcc_convert: | |
| 703 swapf isr1_temp, W | |
| 704 andlw 0x0F ; W= tens | |
| 705 rlncf WREG, W ; W= 2*tens | |
| 706 subwf isr1_temp, F ; 16*tens + ones - 2*tens | |
| 707 subwf isr1_temp, F ; 14*tens + ones - 2*tens | |
| 708 subwf isr1_temp, W ; 12*tens + ones - 2*tens | |
| 709 return | |
| 710 | |
| 711 ;============================================================================= | |
| 712 | |
| 713 isr_switch_right: ; | |
| 714 bcf INTCON,INT0IE ; Disable INT0 | |
| 715 ; bcf power_sw2 ; Power-down switch circuity | |
| 716 banksel common ; flag1 is in Bank1 | |
|
152
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
717 btfss flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
718 bsf switch_right ; Set flag |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
719 btfsc flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
720 bsf switch_left ; Set flag |
| 0 | 721 bra isr_switch_common ; Continue... |
| 722 | |
| 723 isr_switch_left: ; | |
| 724 bcf INTCON3,INT1IE ; Disable INT1 | |
| 725 ; bcf power_sw1 ; Power-down switch circuity | |
| 726 banksel common ; flag1 is in Bank1 | |
|
152
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
727 btfss flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
728 bsf switch_left ; Set flag |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
729 btfsc flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
730 bsf switch_right ; Set flag |
| 0 | 731 |
| 732 isr_switch_common: | |
| 733 ; load timer1 for first press | |
| 734 clrf TMR1L | |
| 735 movlw TMR1H_VALUE_FIRST ; in steps of 7,8125ms | |
| 736 movwf TMR1H | |
| 737 bsf T1CON,TMR1ON ; Start Timer 1 | |
| 738 ; nop | |
| 739 ; nop | |
| 740 ; nop | |
| 741 ; nop | |
| 742 ; nop | |
| 743 ; nop | |
| 744 ; nop | |
| 745 ; nop | |
| 746 ; nop | |
| 747 ; nop | |
| 748 ; nop | |
| 749 ; nop | |
| 750 ; nop | |
| 751 ; nop | |
| 752 ; nop | |
| 753 ; nop | |
| 754 ; nop | |
| 755 ; nop | |
| 756 ; nop | |
| 757 ; nop | |
| 758 ; nop | |
| 759 ; nop | |
| 760 ; nop | |
| 761 ; nop | |
| 762 | |
| 763 banksel isr_backup ; Select Bank0 for ISR data. | |
| 764 ; bsf power_sw1 | |
| 765 bcf INTCON3,INT1IF ; Clear flag | |
| 766 ; bsf power_sw2 ; Power-up switch circuity | |
| 767 bcf INTCON,INT0IF ; Clear flag | |
| 768 return | |
| 769 | |
| 770 timer1int: | |
| 771 bcf PIR1,TMR1IF ; Clear flag | |
| 772 banksel common ; flag1 is in Bank1 | |
| 773 btfss switch_left1 ; Left button hold-down? | |
| 774 bra timer1int_left ; Yes | |
| 775 btfss switch_right2 ; Right button hold-down? | |
| 776 bra timer1int_right ; Yes | |
| 777 | |
| 778 ; No button hold-down, stop Timer 1 | |
| 779 bcf T1CON,TMR1ON ; Stop Timer 1 | |
| 780 bsf INTCON,INT0IE ; Enable INT0 | |
| 781 bsf INTCON3,INT1IE ; Enable INT1 | |
| 782 bcf INTCON,INT0IF ; Clear flag | |
| 783 bcf INTCON3,INT1IF ; Clear flag | |
| 784 return | |
| 785 | |
| 786 timer1int_left: | |
|
152
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
787 btfss flip_screen ; 180° flipped? |
| 0 | 788 bsf switch_left ; (Re-)Set flag |
|
152
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
789 btfsc flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
790 bsf switch_right ; (Re-)Set flag |
| 0 | 791 bra timer1int_common ; Continue |
| 792 timer1int_right: | |
|
152
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
793 btfss flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
794 bsf switch_right ; Set flag |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
795 btfsc flip_screen ; 180° flipped? |
|
19ad15f04f60
BUGFIX: Clear Setpoint-Fallback warning when in bailout
heinrichsweikamp
parents:
148
diff
changeset
|
796 bsf switch_left ; Set flag |
| 0 | 797 timer1int_common: |
| 798 ; load timer1 for next press | |
| 799 clrf TMR1L | |
| 800 movlw TMR1H_VALUE_CONT ; Surface mode | |
| 801 btfsc divemode | |
| 802 movlw TMR1H_VALUE_CONT_DIVE ; Dive mode | |
| 803 movwf TMR1H | |
| 804 ; nop | |
| 805 ; nop | |
| 806 ; nop | |
| 807 ; nop | |
| 808 ; nop | |
| 809 ; nop | |
| 810 ; nop | |
| 811 ; nop | |
| 812 ; nop | |
| 813 ; nop | |
| 814 ; nop | |
| 815 ; nop | |
| 816 ; nop | |
| 817 ; nop | |
| 818 ; nop | |
| 819 ; nop | |
| 820 ; | |
| 821 ; nop | |
| 822 ; nop | |
| 823 ; nop | |
| 824 ; nop | |
| 825 ; nop | |
| 826 ; nop | |
| 827 ; nop | |
| 828 ; nop | |
| 829 ; bsf power_sw1 | |
| 830 bcf INTCON3,INT1IF ; Clear flag | |
| 831 ; bsf power_sw2 ; Power-up switch circuity | |
| 832 bcf INTCON,INT0IF ; Clear flag | |
| 833 return ; Return from timer1int with timer1 kept running | |
| 834 | |
| 835 ;============================================================================= | |
| 836 | |
| 837 check_nofly_desat_time: | |
| 838 movf nofly_time+0,W ; Is nofly null ? | |
| 839 iorwf nofly_time+1,W | |
| 840 bz check_nofly_desat_time2 ; yes... | |
| 841 | |
| 842 movlw d'1' | |
| 843 subwf nofly_time+0,F | |
| 844 movlw d'0' | |
| 845 subwfb nofly_time+1,F ; reduce by one | |
| 846 | |
| 847 check_nofly_desat_time2: | |
| 848 movf desaturation_time+0,W ; Is Desat null ? | |
| 849 iorwf desaturation_time+1,W | |
| 850 bz check_nofly_desat_time3 ; yes... | |
| 851 | |
| 852 movlw d'1' | |
| 853 subwf desaturation_time+0,F | |
| 854 movlw d'0' | |
| 855 subwfb desaturation_time+1,F ; reduce by one... | |
| 856 | |
| 147 | 857 ; Increase surface interval timer |
| 858 infsnz surface_interval+0,F | |
| 859 incf surface_interval+1,F | |
| 0 | 860 return ; Done |
| 861 | |
| 862 check_nofly_desat_time3: | |
| 863 clrf surface_interval+0 | |
| 864 clrf surface_interval+1 ; Clear surface interval timer | |
| 865 return ; Done. | |
| 866 | |
| 867 ;============================================================================= | |
| 868 | |
| 869 isr_restore_clock: | |
| 870 banksel isr_backup | |
| 871 movff speed_setting,isr1_temp ; Copy to Bank0 | |
| 872 movlw d'1' | |
| 873 cpfseq isr1_temp | |
| 874 bra isr_restore_speed2 | |
| 875 ; Reset to eco | |
| 876 movlw b'00000000' | |
| 877 movwf OSCTUNE ; 4x PLL Disable (Bit6) - only works with 8 or 16MHz (=32 or 64MHz) | |
| 878 movlw b'00110010' | |
| 879 movwf OSCCON ; 1MHz INTOSC | |
| 880 movlw T2CON_ECO | |
| 881 movwf T2CON | |
| 882 bra isr_restore_exit | |
| 883 isr_restore_speed2: | |
| 884 movlw d'2' | |
| 885 cpfseq isr1_temp | |
| 886 bra isr_restore_speed3 | |
| 887 ; Reset to normal | |
| 888 movlw b'01110010' | |
| 889 movwf OSCCON ; 16MHz INTOSC | |
| 890 movlw b'00000000' | |
| 891 movwf OSCTUNE ; 4x PLL Disable (Bit6) - only works with 8 or 16MHz (=32 or 64MHz) | |
| 892 movlw T2CON_NORMAL | |
| 893 movwf T2CON | |
| 894 bra isr_restore_exit | |
| 895 | |
| 896 isr_restore_speed3: | |
| 897 ; Reset to fastest | |
| 898 movlw b'01110010' ; 16MHz INTOSC | |
| 899 movwf OSCCON | |
| 900 movlw b'01000000' | |
| 901 movwf OSCTUNE ; 4x PLL Enable (Bit6) - only works with 8 or 16MHz (=32 or 64MHz) | |
| 902 movlw T2CON_FASTEST | |
| 903 movwf T2CON | |
| 904 ; bra isr_restore_exit | |
| 905 isr_restore_exit: | |
| 906 btfss OSCCON,HFIOFS | |
| 907 bra isr_restore_exit ; loop until PLL is stable | |
| 908 return | |
| 909 | |
| 910 END |