Mercurial > public > hwos_code
annotate src/isr.asm @ 646:5b7fe7777425
3.16 release
| author | heinrichs weikamp |
|---|---|
| date | Thu, 14 Oct 2021 12:03:24 +0200 |
| parents | 8c1f1f334275 |
| children | 357341239438 |
| rev | line source |
|---|---|
| 0 | 1 ;============================================================================= |
| 2 ; | |
| 640 | 3 ; File isr.asm * combined next generation V3.11.1 |
| 0 | 4 ; |
| 5 ; INTERUPT subroutines | |
| 6 ; | |
| 7 ; Copyright (c) 2011, JD Gascuel, HeinrichsWeikamp, all right reserved. | |
| 8 ;============================================================================= | |
| 9 ; HISTORY | |
| 10 ; 2011-05-24 : [jDG] Cleanups from initial Matthias code. | |
| 11 | |
| 275 | 12 #include "hwos.inc" |
| 582 | 13 #include "shared_definitions.h" ; Mailbox from/to p2_deco.c |
| 0 | 14 #include "ms5541.inc" |
| 15 #include "adc_lightsensor.inc" | |
| 623 | 16 |
| 17 extern restore_flash | |
| 0 | 18 |
| 634 | 19 |
| 0 | 20 ;============================================================================= |
| 634 | 21 ; Code to be placed at a fixed Position |
| 623 | 22 ; |
| 604 | 23 isr_high CODE 0x0008 ; high priority interrupts |
| 634 | 24 bra HighInt ; jump to ISR |
| 25 | |
| 26 isr_low CODE 0x00018 ; low priority interrupts *** not used *** | |
| 27 retfie FAST ; do an immediate return from IRQ | |
| 28 ; | |
| 29 ;============================================================================= | |
| 623 | 30 |
| 0 | 31 |
| 634 | 32 ;----------------------------------------------------------------------------- |
| 33 ; Interrupt Dispatcher Entry Point | |
| 623 | 34 ; |
| 0 | 35 HighInt: |
| 623 | 36 ; initialize interrupt code |
| 37 banksel isr_backup ; default bank for all ISR code is bank ISR data | |
| 629 | 38 movff PRODL,PROD_backup+0 ; back-up PRODL |
| 39 movff PRODH,PROD_backup+1 ; back-up PRODH | |
| 623 | 40 ; serve buttons |
| 41 btfsc PIR1,TMR1IF ; timer 1 interrupt (button hold-down timer)? | |
| 42 rcall timer1int ; YES - reset timer | |
| 640 | 43 btfsc PIR5,TMR4IF ; timer 4 interrupt (button debounce) |
| 44 rcall timer4int ; YES, serve the interrupt | |
| 623 | 45 btfsc INTCON,INT0IF ; right button activity? |
| 46 rcall isr_switch_right ; YES - check right switch | |
| 47 btfsc INTCON3,INT1IF ; left button activity? | |
| 48 rcall isr_switch_left ; YES - check left switch | |
| 0 | 49 |
| 623 | 50 IFDEF _external_sensor |
| 51 ; serve IR/S8 link timer | |
| 52 btfsc PIR3,RC2IF ; UART 2 interrupt? | |
| 53 rcall isr_uart2 ; YES - get a byte from the IR/S8 link | |
| 54 btfsc PIR2,TMR3IF ; timer 3 interrupt? | |
| 55 rcall isr_timer3 ; YES - check bytes received from IR/S8 link for being a valid telegram | |
| 629 | 56 ELSE |
| 57 bcf PIR3,RC2IF ; clear UART 2 interrupt | |
| 58 bcf PIR2,TMR3IF ; clear timer 3 interrupt | |
| 59 ; fill-up to keep code size identical to _external_sensor variant, see "Attention" below | |
| 60 nop | |
| 61 nop | |
| 623 | 62 ENDIF |
| 63 | |
| 64 ; serve pressure and temperature sensor | |
| 65 btfsc PIR5,TMR7IF ; timer 7 interrupt? | |
| 66 rcall isr_tmr7 ; YES - do every 62.5 ms tasks: read sensors, set CPU speed | |
| 67 | |
| 68 ; serve real-time clock (RTCC) | |
| 69 btfsc PIR3,RTCCIF ; real-time-clock interrupt? | |
| 70 rcall isr_rtcc ; YES - do every 1/2 s tasks: read RTC, trigger timed tasks, adjust CPU speed, gauge battery, etc. | |
| 113 | 71 |
| 623 | 72 ; clean up and exit |
| 629 | 73 movff PROD_backup+0,PRODL ; restore PRODL |
| 74 movff PROD_backup+1,PRODH ; restore PRODH | |
| 623 | 75 bsf trigger_isr_updates ; signal that the ISR had kicked in |
| 76 retfie FAST ; return from interrupt restoring BSR, STATUS and WREG | |
| 77 | |
| 113 | 78 |
| 634 | 79 ;----------------------------------------------------------------------------- |
| 80 ; CPU Speed Adjustment | |
| 623 | 81 ; |
| 82 isr_adjust_speed: | |
| 83 movff cpu_speed_request,cpu_speed_state ; acknowledge CPU speed request | |
| 0 | 84 |
| 623 | 85 btfsc speed_is_eco ; speed 'eco' requested? |
| 86 bra isr_set_speed_to_eco ; YES - set eco speed | |
| 87 btfsc speed_is_fastest ; NO - speed 'fastest' requested? | |
| 88 bra isr_set_speed_to_fastest ; YES - set fastest speed | |
| 89 ;bra isr_set_speed_to_normal ; NO - default to normal speed | |
| 0 | 90 |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
91 isr_set_speed_to_normal: |
| 629 | 92 clrf OSCTUNE ; switch off x4 PLL |
| 623 | 93 movlw b'01110010' ; select 16 MHz |
| 94 movwf OSCCON ; set prescaler | |
| 95 movlw T2CON_NORMAL ; PWM1 dimming factor for speed 'normal' | |
| 96 bra isr_adjust_speed_exit | |
| 97 | |
| 98 isr_set_speed_to_eco: | |
| 629 | 99 clrf OSCTUNE ; switch off x4 PLL |
| 623 | 100 movlw b'00110010' ; select 1 MHz |
| 101 movwf OSCCON ; set prescaler | |
| 102 movlw T2CON_ECO ; PWM1 dimming factor for speed 'eco' | |
| 103 bra isr_adjust_speed_exit | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
104 |
| 623 | 105 isr_set_speed_to_fastest: |
| 106 movlw b'01110010' ; select 16 MHz by default | |
| 107 btfsc lv_core ; on OSTC with low voltage core? | |
| 108 movlw b'01100010' ; YES - reduce to 8 MHz | |
| 109 movwf OSCCON ; set prescaler | |
| 629 | 110 bsf OSCTUNE,6 ; switch on x4 PLL -> 64 MHz on high voltage core, 32 MHz on low voltage core |
| 623 | 111 movlw T2CON_FASTEST ; PWM1 dimming factor for speed 'fastest' |
| 640 | 112 bra isr_adjust_speed_exit |
| 623 | 113 |
| 114 ; Attention: fill-up the gap between the end of this section | |
| 115 ; and the next section which starts at 0x00080 !! | |
| 640 | 116 nop |
| 117 | |
| 623 | 118 block_0_code_end: ; marker to find end of code in block 0 in linker report file |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
119 |
| 634 | 120 |
| 623 | 121 ;============================================================================= |
| 634 | 122 ; Code to be placed at a fixed Position: Jump-Vector for the Bootloader |
| 623 | 123 ; |
| 634 | 124 restore CODE 0x00080 ; restore first flash page from EEPROM |
| 125 | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
126 restore_flash_0x00080: |
| 582 | 127 goto restore_flash |
| 634 | 128 ; |
| 129 ;============================================================================= | |
| 130 | |
|
410
d3087a8ed7e1
BUGFIX: Fix rare issue after battery change (OSTC3 did not start properly)
heinrichsweikamp
parents:
378
diff
changeset
|
131 |
| 623 | 132 ;============================================================================= |
| 634 | 133 isr_handler CODE 0x00084 |
| 134 ;============================================================================= | |
| 135 | |
| 640 | 136 isr_adjust_speed_exit: |
| 137 movwf T2CON ; adjust PWM1 for LED dimming | |
| 138 btfss OSCCON,HFIOFS ; PLL stabilized? | |
| 139 bra isr_adjust_speed_exit ; NO - loop to give it some more time | |
| 140 return ; YES - done | |
| 141 | |
| 634 | 142 ;----------------------------------------------------------------------------- |
| 143 ; Handle digitally-attached external Sensors | |
| 144 ; | |
| 145 ; take a byte received on IR/S8 link and slot it into the RX buffer | |
| 623 | 146 ; |
| 147 IFDEF _external_sensor | |
| 148 | |
| 149 isr_uart2: | |
| 634 | 150 bcf PIR3,RC2IF ; clear UART 2 interrupt flag |
| 623 | 151 banksel RCREG2 ; RC*2 is outside access RAM |
| 152 movff RCREG2,isr_lo ; copy received byte to isr_lo | |
| 153 bcf RCSTA2,CREN ; clear receiver status | |
| 154 bsf RCSTA2,CREN ; ... | |
| 155 banksel isr_backup ; back to default ISR bank | |
| 156 movlw .18 ; size of the buffer | |
| 157 cpfslt ir_s8_counter ; number of received bytes < buffer size? | |
| 158 bra isr_uart2_1 ; NO - buffer full, do not store the byte | |
| 159 movf ir_s8_counter,W ; YES - copy number of received bytes to WREG | |
| 160 MOVII FSR0L,FSR0_backup ; - back-up FSR0 | |
| 161 lfsr FSR0,ir_s8_buffer ; - load base address of buffer | |
| 162 movff isr_lo,PLUSW0 ; - store received byte | |
| 163 MOVII FSR0_backup,FSR0L ; - restore FSR0 | |
| 164 incf ir_s8_counter,F ; - increment number of received bytes by 1 | |
| 165 isr_uart2_1: | |
| 634 | 166 movlw .253 ; reload timer 3, high byte |
| 623 | 167 movwf TMR3H ; ... |
| 634 | 168 clrf TMR3L ; reload timer 3, low byte |
| 169 bsf T3CON,TMR3ON ; restart timer | |
| 170 return ; done | |
| 623 | 171 |
| 172 | |
| 634 | 173 ;----------------------------------------------------------------------------- |
| 174 ; Timeout on IR/S8 Link: check the Checksum and gather the received Data | |
| 623 | 175 ; |
| 176 isr_timer3: | |
| 604 | 177 bcf T3CON,TMR3ON ; stop timer 3 |
| 634 | 178 movlw .15 ; a IR telegram has 15 bytes |
| 604 | 179 cpfseq ir_s8_counter ; got exactly 15 bytes? |
| 623 | 180 bra isr_timer3_1 ; NO - test for 16 bytes |
| 604 | 181 bra isr_timer3_ir ; YES - got 15 bytes, compute local checksum |
| 0 | 182 isr_timer3_1: |
| 634 | 183 movlw .16 ; a IR telegram may also have 16 bytes, with last byte 0x00 |
| 604 | 184 cpfseq ir_s8_counter ; got exactly 16 bytes? |
| 623 | 185 bra isr_timer3_2 ; NO - test for 17 bytes |
| 604 | 186 tstfsz ir_s8_buffer+.15 ; YES - last byte = 0x00 ? |
| 634 | 187 bra isr_timer3_exit ; NO - exit |
| 604 | 188 bra isr_timer3_ir ; YES - got 16 bytes, compute local checksum |
| 113 | 189 isr_timer3_2: |
| 634 | 190 movlw .17 ; a S8 telegram has 17 bytes |
| 604 | 191 cpfseq ir_s8_counter ; got exactly 17 bytes? |
| 192 bra isr_timer3_exit ; NO - exit | |
| 193 bra isr_timer3_s8 ; YES - S8 data | |
| 0 | 194 |
| 634 | 195 ; process telegram received on IR link |
| 623 | 196 isr_timer3_ir: |
| 634 | 197 movlw .12 ; compute checksum over 1st and next 12 bytes |
| 623 | 198 rcall compute_IR_S8_checksum ; compute checksum |
| 634 | 199 tstfsz ir_s8_counter ; checksum ok? |
| 200 bra isr_timer3_exit ; NO - discard data | |
| 0 | 201 |
| 634 | 202 ; copy received data to respective variables |
| 623 | 203 movff ir_s8_buffer+.1, hud_status_byte |
| 204 movff ir_s8_buffer+.2, sensor1_mv+0 | |
| 205 movff ir_s8_buffer+.3, sensor1_mv+1 | |
| 206 movff ir_s8_buffer+.4, sensor2_mv+0 | |
| 207 movff ir_s8_buffer+.5, sensor2_mv+1 | |
| 208 movff ir_s8_buffer+.6, sensor3_mv+0 | |
| 209 movff ir_s8_buffer+.7, sensor3_mv+1 | |
| 210 movff ir_s8_buffer+.8, sensor1_ppO2 | |
| 211 movff ir_s8_buffer+.9, sensor2_ppO2 | |
| 212 movff ir_s8_buffer+.10,sensor3_ppO2 | |
| 582 | 213 movff ir_s8_buffer+.11,hud_battery_mv+0 |
| 214 movff ir_s8_buffer+.12,hud_battery_mv+1 | |
| 0 | 215 |
| 623 | 216 bsf hud_connection_ok ; set manually for hwHUD w/o the HUD module |
| 217 bra isr_timer3_reload ; reload timer and exit | |
| 218 | |
| 634 | 219 ; process telegram received on S8 link |
| 623 | 220 isr_timer3_s8: |
| 634 | 221 movlw .14 ; compute checksum over 1st and next 14 bytes |
| 623 | 222 rcall compute_IR_S8_checksum ; compute checksum |
| 634 | 223 tstfsz ir_s8_counter ; checksum ok? |
| 224 bra isr_timer3_exit ; NO - discard data | |
| 623 | 225 |
| 634 | 226 ; copy received data to respective variables |
| 227 movff ir_s8_buffer+.3, hud_status_byte ; also sets hud_connection_ok flag | |
| 623 | 228 movff ir_s8_buffer+.13,hud_battery_mv+0 |
| 229 movff ir_s8_buffer+.14,hud_battery_mv+1 | |
|
227
03946aa48fa5
NEW: Support for hwHUD without the LED module
heinrichsweikamp
parents:
204
diff
changeset
|
230 |
| 634 | 231 ; btfsc trigger_S8_data_update ; last data already processed? |
| 232 ; bra isr_timer3_exit ; NO - skip copying new data (and not reload the timeout) | |
| 623 | 233 bsf trigger_S8_data_update ; YES - set flag for new data available |
| 582 | 234 |
| 634 | 235 ; copy more received data to respective variables |
| 623 | 236 movff ir_s8_buffer+.4, s8_rawdata_sensor1+0 |
| 237 movff ir_s8_buffer+.5, s8_rawdata_sensor1+1 | |
| 238 movff ir_s8_buffer+.6, s8_rawdata_sensor1+2 | |
| 239 movff ir_s8_buffer+.7, s8_rawdata_sensor2+0 | |
| 240 movff ir_s8_buffer+.8, s8_rawdata_sensor2+1 | |
| 241 movff ir_s8_buffer+.9, s8_rawdata_sensor2+2 | |
| 242 movff ir_s8_buffer+.10,s8_rawdata_sensor3+0 | |
| 243 movff ir_s8_buffer+.11,s8_rawdata_sensor3+1 | |
| 244 movff ir_s8_buffer+.12,s8_rawdata_sensor3+2 | |
| 245 | |
| 246 isr_timer3_reload: | |
| 634 | 247 movlw ir_timeout_value ; get timeout value (in multiples of 62.5 ms) |
| 248 movwf ir_s8_timeout ; reload timeout counter | |
| 0 | 249 isr_timer3_exit: |
| 634 | 250 clrf ir_s8_counter ; clear number of received bytes |
| 251 bcf PIR2,TMR3IF ; clear IRQ flag | |
| 252 return ; done | |
| 0 | 253 |
| 254 | |
| 634 | 255 ;----------------------------------------------------------------------------- |
| 256 ; Helper Function - Compute Checksum on Data in RX Buffer | |
| 623 | 257 ; |
| 258 compute_IR_S8_checksum: | |
| 259 movwf ir_s8_counter ; initialize loop counter from WREG | |
| 634 | 260 MOVII FSR0L,FSR0_backup ; back-up FSR0 |
| 261 lfsr FSR0,ir_s8_buffer ; load base address of the receive buffer | |
| 262 movff POSTINC0,isr_mpr+0 ; initialize low byte of the calculated checksum with first byte in buffer | |
| 263 clrf isr_mpr+1 ; clear the high byte of the calculated checksum | |
| 623 | 264 compute_IR_S8_checksum_loop: |
| 634 | 265 movf POSTINC0,W ; read next byte |
| 623 | 266 addwf isr_mpr+0,F ; add it to the to checksum, low byte |
| 267 movlw .0 ; no explicit data to add to the high byte... | |
| 268 addwfc isr_mpr+1,F ; ... besides the carry | |
| 634 | 269 decfsz ir_s8_counter,F ; decrement number of bytes yet to do, all done? |
| 623 | 270 bra compute_IR_S8_checksum_loop ; NO - loop |
| 634 | 271 movf POSTINC0,W ; YES - read low byte of the received checksum |
| 272 cpfseq isr_mpr+0 ; - equal to low byte of the calculated checksum? | |
| 273 incf ir_s8_counter,F ; NO - mark a checksum error | |
| 274 movf POSTINC0,W ; - read high byte of the received checksum | |
| 275 cpfseq isr_mpr+1 ; - equal to high byte of the calculated checksum? | |
| 276 incf ir_s8_counter,F ; NO - mark a checksum error | |
| 277 MOVII FSR0_backup,FSR0L ; - restore FSR0 | |
| 278 return ; - done | |
| 113 | 279 |
| 623 | 280 ENDIF ; _external_sensor |
| 113 | 281 |
| 640 | 282 |
| 283 ;----------------------------------------------------------------------------- | |
| 284 ; Timer 4 - Button debounce (For new digital piezo circuit) | |
| 285 | |
| 286 timer4int: | |
| 287 bcf PIR5,TMR4IF | |
| 288 decfsz debounce_counter,F | |
| 289 return | |
| 290 bcf T4CON,TMR4ON ; Stop timer 4 | |
| 291 clrf TMR4 ; reset | |
| 292 | |
| 293 movff opt_cR_button_right,WREG ; 20-100; mH: opt_cR_button_right will also affect left button | |
| 294 bcf STATUS,C ; clear carry bit | |
| 295 rrcf WREG ; /2 -> 10-50 | |
| 296 bcf STATUS,C ; clear carry bit | |
| 297 rrcf WREG ; /2 -> 5-25 | |
| 298 decf WREG,W ; -1 | |
| 299 decf WREG,W ; -1 | |
| 300 decf WREG,W ; -1 -> 2-22 | |
| 301 | |
| 302 ; movlw .5 ; initial delay | |
| 303 movwf debounce_counter ; multiples of 16ms | |
| 304 return | |
| 305 | |
| 306 timer4_restart: | |
| 307 movlw .5 ; extra delay | |
| 308 movwf debounce_counter | |
| 309 clrf TMR4 ; reset | |
| 310 bcf INTCON3,INT1IF ; clear ext. int 1 request | |
| 311 bcf INTCON,INT0IF ; clear ext. int 0 request | |
| 312 bsf INTCON,INT0IE ; enable INT0 IRQ | |
| 313 bsf INTCON3,INT1IE ; enable INT1 IRQ | |
| 314 return | |
| 0 | 315 |
| 634 | 316 ;----------------------------------------------------------------------------- |
| 317 ; Tasks every 62.5 ms: Buttons, Dimming, Pressure/Temperature Sensor and CPU Speed | |
| 623 | 318 ; |
| 319 isr_tmr7: | |
| 634 | 320 bcf PIE5,TMR7IE ; disable IRQs by TMR7 |
| 0 | 321 |
| 634 | 322 banksel 0xF16 ; TMR7H/L are not part of the access RAM |
| 323 movlw .248 ; reload timer 7, high byte (8x256 ticks -> 62.5 ms) | |
| 324 movwf TMR7H ; ... (keep low byte running ) | |
| 325 | |
| 646 | 326 banksel isr_backup ; back to ISR default bank |
| 327 decfsz isr_tmr7_helper,F ; decreased every 62,5ms | |
| 328 bra isr_tmr7_0 | |
| 329 movlw .4 ; 62,5ms * 4 = 1/4 second | |
| 330 movwf isr_tmr7_helper | |
| 331 bsf trigger_quarter_second ; set flag (In access RAM) | |
| 332 | |
| 333 | |
| 334 isr_tmr7_0: | |
| 640 | 335 btfss update_surface_pressure ; shall update the surface pressure? |
| 336 bra isr_tmr7_1 ; NO - skip | |
| 337 bcf update_surface_pressure ; YES - clear request flag | |
| 338 MOVII pressure_abs_ref,pressure_surf ; - update surface pressure | |
| 636 | 339 |
| 640 | 340 isr_tmr7_1: |
| 634 | 341 call get_analog_switches ; get analog readings - bank-safe, but CAUTION: returns in bank common |
| 342 banksel isr_backup ; back to ISR default bank | |
| 623 | 343 |
| 634 | 344 btfss INTCON3,INT1IE ; external IRQ 1 enabled? |
| 640 | 345 bra isr_tmr7_2 ; NO - skip next |
| 634 | 346 btfsc analog_sw2_pressed ; YES - analog switch 2 pressed? |
| 347 rcall isr_switch_left ; NO - get digital readings of left switch | |
| 640 | 348 |
| 349 isr_tmr7_2: | |
| 634 | 350 btfss INTCON,INT0IE ; external IRQ 0 enabled? |
| 640 | 351 bra isr_tmr7_3 ; NO - skip next |
| 634 | 352 btfsc analog_sw1_pressed ; YES - analog switch 1 pressed? |
| 353 rcall isr_switch_right ; NO - get digital readings of right switch | |
| 640 | 354 |
| 355 isr_tmr7_3: | |
| 356 btfsc block_sensor_interrupt ; sensor interrupts disabled? | |
| 634 | 357 bra sensor_int_state_exit ; YES - goto exit |
| 640 | 358 ;bra isr_tmr7_4 ; NO - continue |
| 359 | |
| 360 isr_tmr7_4: | |
| 623 | 361 movf max_CCPR1L,W ; dim value |
| 582 | 362 cpfseq CCPR1L ; = current PWM value? |
| 623 | 363 rcall isr_dimm_tft ; NO - adjust until max_CCPR1L = CCPR1L |
| 0 | 364 |
| 623 | 365 IFDEF _external_sensor |
| 640 | 366 |
| 634 | 367 decfsz ir_s8_timeout,F ; decrement IR/S8 timeout counter, became zero? |
| 640 | 368 bra isr_sensor_state2 ; NO - continue with sensor |
| 634 | 369 movlw ir_timeout_value ; YES - get timeout value (in multiples of 62.5 ms) |
| 370 movwf ir_s8_timeout ; - reload timeout timer | |
| 371 btfsc ext_input_optical ; - optical input in use? | |
| 640 | 372 bra isr_tmr7_5 ; YES - clear data |
| 634 | 373 TSTOSS opt_s8_mode ; NO - S8 input in use? |
| 640 | 374 bra isr_sensor_state2 ; NO - must be analog interface in use, keep data |
| 375 ;bra isr_tmr7_5 ; YES - clear data | |
| 634 | 376 |
| 640 | 377 isr_tmr7_5: |
| 623 | 378 clrf hud_status_byte ; S8/IR timeout clears all analog input readings to zero -> fallback will be triggered when in sensor mode |
| 379 CLRI hud_battery_mv ; clear battery voltage | |
| 582 | 380 |
| 623 | 381 banksel sensor1_mv ; select bank where sensor data are stored |
| 382 CLRI sensor1_mv ; clear all sensor data | |
| 383 CLRI sensor2_mv ; ... | |
| 384 CLRI sensor3_mv ; ... | |
| 385 clrf sensor1_ppO2 ; ... | |
| 386 clrf sensor2_ppO2 ; ... | |
| 387 clrf sensor3_ppO2 ; ... | |
| 628 | 388 banksel s8_rawdata_sensor1 |
| 389 CLRI s8_rawdata_sensor1 ; clear all sensor data (raw data) | |
| 390 clrf s8_rawdata_sensor1+2 | |
| 391 CLRI s8_rawdata_sensor2 ; clear all sensor data (raw data) | |
| 392 clrf s8_rawdata_sensor2+2 | |
| 393 CLRI s8_rawdata_sensor3 ; clear all sensor data (raw data) | |
| 394 clrf s8_rawdata_sensor3+2 | |
| 623 | 395 banksel isr_backup ; back to ISR default bank |
| 396 | |
| 397 bsf trigger_S8_data_update ; signal a data update | |
| 582 | 398 |
| 640 | 399 ENDIF ; _external_sensor |
| 0 | 400 |
| 640 | 401 isr_sensor_state2: |
| 623 | 402 btfss speed_is_normal ; CPU running on normal speed? |
| 403 rcall isr_set_speed_to_normal ; NO - set CPU speed to normal | |
| 582 | 404 |
| 623 | 405 incf sensor_state_counter,F ; counts to eight for state machine |
| 0 | 406 |
| 623 | 407 ; State 1: clear flags and average registers, get temperature (51 us) and start pressure integration (73.5 us) |
| 408 ; State 2: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 409 ; State 3: get temperature (51 us) and start pressure integration (73.5 us) | |
| 410 ; State 4: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 411 ; State 5: get temperature (51 us) and start pressure integration (73.5 us) | |
| 412 ; State 6: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) | |
| 413 ; State 7: get temperature (51 us) and start pressure integration (73.5 us) | |
| 414 ; State 8: get pressure (51 us), start temperature integration (73.5 us) and calculate temperature compensated pressure (233 us) and build average for half-second update of temperature and pressure | |
| 582 | 415 |
| 623 | 416 movff sensor_state_counter,WREG ; WREG used as temp here... |
| 582 | 417 dcfsnz WREG,F |
| 623 | 418 bra sensor_int_state1_plus_restart ; do state 1 |
| 582 | 419 dcfsnz WREG,F |
| 623 | 420 bra sensor_int_state2 ; do state 2 |
| 582 | 421 dcfsnz WREG,F |
| 623 | 422 bra sensor_int_state1 ; do state 3 |
| 582 | 423 dcfsnz WREG,F |
| 623 | 424 bra sensor_int_state2 ; do state 4 |
| 582 | 425 dcfsnz WREG,F |
| 623 | 426 bra sensor_int_state1 ; do state 5 |
| 582 | 427 dcfsnz WREG,F |
| 623 | 428 bra sensor_int_state2 ; do state 6 |
| 582 | 429 dcfsnz WREG,F |
| 623 | 430 bra sensor_int_state1 ; do state 7 |
| 431 | |
| 432 ; first, do state 2: | |
| 433 call get_pressure_value ; state 2: get pressure (51 us) | |
| 434 call get_temperature_start ; and start temperature integration (73.5 us) | |
| 435 call calculate_compensation ; calculate temperature compensated pressure (27 us) | |
| 0 | 436 |
| 634 | 437 ; build average for pressure |
| 646 | 438 ;bcf STATUS,C ; clear carry bit - not needed since we don't use the +2 register later |
| 439 rrcf pressure_abs_avg+2 ; divide by 2 | |
| 440 rrcf pressure_abs_avg+1 ; ... | |
| 634 | 441 rrcf pressure_abs_avg+0 ; ... |
| 646 | 442 ;bcf STATUS,C ; clear carry bit - not needed since we don't use the +2 register later |
| 443 rrcf pressure_abs_avg+2 ; divide by 2, again | |
| 444 rrcf pressure_abs_avg+1 ; ... | |
| 634 | 445 rrcf pressure_abs_avg+0 ; ... |
| 623 | 446 |
| 634 | 447 ; export averaged pressure |
| 646 | 448 MOVII pressure_abs_avg,pressure_abs ; export result (Which is 16 bit for all depths < 262m) |
| 0 | 449 |
| 634 | 450 ; build average for temperature |
| 623 | 451 bcf STATUS,C ; clear carry bit by default |
| 452 btfsc temperature_avg+1,7 ; sign bit set? | |
| 453 bsf STATUS,C ; YES - copy sign bit to carry bit | |
| 454 rrcf temperature_avg+1 ; divide signed temperature by 2 | |
| 455 rrcf temperature_avg+0 ; ... | |
| 456 bcf STATUS,C ; clear carry bit by default | |
| 457 btfsc temperature_avg+1,7 ; sign bit set? | |
| 458 bsf STATUS,C ; YES - copy sign bit to carry bit | |
| 459 rrcf temperature_avg+1 ; divide signed temperature by 2 again (by 4 in total now) | |
| 460 rrcf temperature_avg+0 ; ... | |
| 461 MOVII temperature_avg,temperature_cur ; store final result | |
| 0 | 462 |
| 634 | 463 ; check for temperature change |
| 623 | 464 movf temperature_cur+0,W ; get current temperature, low byte |
| 465 cpfseq temperature_last+0 ; compare with last temperature, equal? | |
| 466 bra isr_sensor_state2_2 ; NO - temperature has changed | |
| 467 movf temperature_cur+1,W ; get current temperature, high byte | |
| 468 cpfseq temperature_last+1 ; compare with last temperature, equal? | |
| 469 bra isr_sensor_state2_2 ; NO - temperature has changed | |
| 470 bra isr_sensor_state2_3 ; YES to both - no change | |
| 0 | 471 |
| 472 isr_sensor_state2_2: | |
| 623 | 473 MOVII temperature_cur,temperature_last ; store current temperature as last temperature for next round |
| 474 bsf trigger_temp_changed ; set flag for temperature change | |
| 475 | |
| 0 | 476 isr_sensor_state2_3: |
| 629 | 477 ; reset state counter |
| 623 | 478 clrf sensor_state_counter ; reset state counter |
| 479 btfss reset_max_pressure ; shall clear the max pressure? | |
| 480 bra isr_sensor_state2_3a ; NO - continue with checking for pressure change | |
| 481 bcf reset_max_pressure ; YES - clear request flag | |
| 482 CLRI pressure_rel_max ; - clear max. pressure | |
| 0 | 483 |
| 623 | 484 isr_sensor_state2_3a: |
| 485 ; check for pressure change | |
| 486 movf pressure_abs+0,W ; get current pressure, low byte | |
| 487 cpfseq pressure_abs_last+0 ; compare with last pressure, equal? | |
| 488 bra isr_sensor_state2_4 ; NO - pressure has changed | |
| 489 movf pressure_abs+1,W ; YES - get current pressure, high byte | |
| 490 cpfseq pressure_abs_last+1 ; - compare with last pressure, equal? | |
| 491 bra isr_sensor_state2_4 ; NO - pressure has changed | |
| 492 bra isr_sensor_state2_5 ; YES - no change | |
| 493 | |
| 494 isr_sensor_state2_4: | |
| 495 MOVII pressure_abs,pressure_abs_last ; store current pressure as last pressure for next round | |
| 496 bsf trigger_pres_cur_changed ; signal a pressure change | |
| 497 | |
| 498 isr_sensor_state2_5: | |
| 499 ; compute relative pressure | |
| 500 movf pressure_surf+0,W ; get surface pressure, low byte | |
| 501 subwf pressure_abs+0,W ; WREG = pressure_abs - pressure_surf (low byte) | |
| 502 movwf pressure_rel_cur+0 ; store relative pressure, low byte | |
| 503 movf pressure_surf+1,W ; get surface pressure, high byte | |
| 504 subwfb pressure_abs+1,W ; WREG = pressure_abs - pressure_surf (high byte) | |
| 505 movwf pressure_rel_cur+1 ; store relative pressure, high byte | |
| 506 btfss STATUS,N ; relative pressure < 0 ? | |
| 507 bra isr_sensor_state2_6 ; NO - OK, keep result | |
| 508 CLRI pressure_rel_cur ; YES - set relative pressure to zero | |
| 0 | 509 |
| 623 | 510 isr_sensor_state2_6: |
| 511 ; check for new max relative pressure | |
| 512 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 513 subwf pressure_rel_max+0,W ; WREG = pressure_rel_max - pressure_rel_cur (low byte) | |
| 514 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 515 subwfb pressure_rel_max+1,W ; WREG = pressure_rel_max - pressure_rel_cur (high byte) | |
| 516 btfss STATUS,N ; result < 0, i.e. new max rel pressure? | |
| 517 bra isr_sensor_state2_6a ; NO | |
| 518 MOVII pressure_rel_cur,pressure_rel_max ; YES - set new max rel pressure | |
| 519 bsf trigger_pres_max_changed ; - signal a pressure max change | |
| 520 | |
| 521 isr_sensor_state2_6a: | |
| 0 | 522 |
| 623 | 523 IFDEF _min_depth_option |
| 524 ; check if min/max pressures shall be reset | |
| 525 btfss reset_trip_pressure ; shall reset the resettable min/max pressures? | |
| 526 bra isr_sensor_state2_6b ; NO | |
| 527 bcf reset_trip_pressure ; YES - clear request flag | |
| 528 CLRI pressure_rel_max_trip ; - set max pressure to zero | |
| 529 SETI pressure_rel_min_trip ; - set min pressure to biggest value possible | |
| 530 isr_sensor_state2_6b: | |
| 531 ; check for new resettable max relative pressure | |
| 532 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 533 subwf pressure_rel_max_trip+0,W ; WREG = pressure_rel_max - pressure_rel_cur (low byte) | |
| 534 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 535 subwfb pressure_rel_max_trip+1,W ; WREG = pressure_rel_max - pressure_rel_cur (high byte) | |
| 536 btfss STATUS,N ; result < 0, i.e. new max rel pressure? | |
| 537 bra isr_sensor_state2_6c ; NO - continue checking for min depth | |
| 538 MOVII pressure_rel_cur,pressure_rel_max_trip ; YES - set new max rel pressure | |
| 539 isr_sensor_state2_6c: | |
| 540 ; check for new resettable min relative pressure | |
| 541 movf pressure_rel_cur+0,W ; get current relative pressure, low byte | |
| 542 subwf pressure_rel_min_trip+0,W ; WREG = pressure_rel_min - pressure_rel_cur (low byte) | |
| 543 movf pressure_rel_cur+1,W ; get current relative pressure, high byte | |
| 544 subwfb pressure_rel_min_trip+1,W ; WREG = pressure_rel_min - pressure_rel_cur (high byte) | |
| 545 btfss STATUS,C ; result > 0, i.e. new min rel pressure? | |
| 546 bra sensor_int_state_exit ; NO - done | |
| 547 MOVII pressure_rel_cur,pressure_rel_min_trip ; YES - set new min rel pressure | |
| 548 ENDIF ; _min_depth_option | |
| 549 bra sensor_int_state_exit ; done | |
| 0 | 550 |
| 551 sensor_int_state1_plus_restart: | |
| 646 | 552 clrf pressure_abs_avg+0 ; clear pressure average register |
| 553 clrf pressure_abs_avg+1 | |
| 554 clrf pressure_abs_avg+2 | |
| 634 | 555 CLRI temperature_avg ; clear average register for temperature |
| 0 | 556 |
| 557 sensor_int_state1: | |
| 646 | 558 call get_temperature_value ; state 1: get temperature... |
| 604 | 559 call get_pressure_start ; ...and start pressure integration |
| 582 | 560 bra sensor_int_state_exit |
| 0 | 561 |
| 562 sensor_int_state2: | |
| 604 | 563 call get_pressure_value ; state 2: get pressure (51 us)... |
| 564 call get_temperature_start ; ...and start temperature integration (73.5 us) | |
| 565 call calculate_compensation ; .. and calculate temperature compensated pressure (233 us) | |
| 582 | 566 |
| 0 | 567 sensor_int_state_exit: |
| 634 | 568 bcf PIR5,TMR7IF ; clear IRQ flag |
| 569 bsf PIE5,TMR7IE ; re-enable IRQs by TMR7 | |
| 623 | 570 bra isr_adjust_speed ; set/restore CPU speed and return |
| 571 | |
| 572 | |
| 634 | 573 ;----------------------------------------------------------------------------- |
| 574 ; Helper Function for Display Dimming | |
| 575 ; | |
| 623 | 576 isr_dimm_tft: ; adjust until max_CCPR1L = CCPR1L |
| 628 | 577 btfsc screen_type3 ; screen type 3 ? |
| 578 return ; YES - ignore, no dimming function with screen type 3 | |
| 623 | 579 btfsc tft_is_dimming ; is the display dimming? |
| 580 return ; YES - ignore | |
| 581 movf max_CCPR1L,W ; NO - proceed | |
| 628 | 582 cpfsgt CCPR1L ; - CCPR1L > max_CCPR1L ? |
| 583 bra isr_dimm_tft2 ; NO - dim up | |
| 584 decf CCPR1L,F ; YES - dim down | |
| 585 return ; - done | |
| 623 | 586 isr_dimm_tft2: |
| 628 | 587 movf max_CCPR1L,W ; |
| 588 sublw ambient_light_min_eco ; | |
| 623 | 589 cpfsgt CCPR1L ; CCPR1L > max_CCPR1L - ambient_light_min_eco ? |
| 590 bra isr_dimm_tft3 ; NO - dim up slow | |
| 628 | 591 movlw .10 ; YES - dim up faster (+10) |
| 592 addwf CCPR1L,F ; - add to dimming value | |
| 623 | 593 isr_dimm_tft3: |
| 628 | 594 incf CCPR1L,F ; - dim up (+1) |
| 595 return ; - done | |
| 623 | 596 |
| 582 | 597 |
| 634 | 598 ;----------------------------------------------------------------------------- |
| 599 ; RTC Interrupt (invoked every 0.5 Seconds) | |
| 623 | 600 ; |
| 601 isr_rtcc: | |
| 602 bcf PIR3,RTCCIF ; clear flag | |
| 603 bsf trigger_half_second ; set flag for a new 1/2 second has begun | |
| 604 btfsc reset_timebase ; shall reset the timebase? | |
| 605 bra isr_rtcc_1 ; YES - warp to new full second | |
| 606 btg timebase_0sec ; NO - toggle the 1/2 second timebase | |
| 607 btfsc timebase_0sec ; - did it toggled 1 -> 0 ? | |
| 608 return ; NO - on half second, done | |
| 0 | 609 |
| 623 | 610 isr_rtcc_1: |
| 611 ; new full second | |
| 612 bsf trigger_full_second ; set flag for a new 1/1 second has begun | |
| 613 | |
| 614 btfsc block_rtc_access ; ISR suspended from accessing the RTC? | |
| 615 bra isr_rtcc_2 ; YES | |
| 616 | |
| 617 banksel RTCCFG ; RTC registers are outside access RAM | |
| 582 | 618 bsf RTCCFG,RTCPTR1 |
| 623 | 619 bsf RTCCFG,RTCPTR0 |
| 620 banksel isr_backup ; back to ISR default bank | |
| 621 | |
| 622 movff RTCVALL,rtc_year ; read year in BCD | |
| 623 movff RTCVALH,rtc_day ; dummy read | |
| 624 movff RTCVALL,rtc_day ; read day in BCD | |
| 625 movff RTCVALH,rtc_month ; read month in BCD | |
| 626 movff RTCVALL,rtc_hour ; read hour in BCD | |
| 627 movff RTCVALH,rtc_secs ; dummy read | |
| 628 movff RTCVALL,rtc_secs ; read seconds in BCD | |
| 629 movff RTCVALH,rtc_mins ; read minutes in BCD | |
| 582 | 630 |
| 634 | 631 ; convert BCD to DEC and set registers |
| 623 | 632 movf rtc_mins,W |
| 633 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 634 movwf rtc_mins | |
| 635 movf rtc_secs,W | |
| 636 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 637 movwf rtc_secs | |
| 638 movf rtc_hour,W | |
| 639 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 640 movwf rtc_hour | |
| 641 movf rtc_month,W | |
| 642 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 643 movwf rtc_month | |
| 644 movf rtc_day,W | |
| 645 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 646 movwf rtc_day | |
| 647 movf rtc_year,W | |
| 648 rcall isr_rtcc_convert_BCD_DEC ; convert to decimal with result in WREG | |
| 649 movwf rtc_year | |
| 650 | |
| 651 isr_rtcc_2: | |
| 629 | 652 ; every full second - get ambient light level and set max_CCPR1L |
| 623 | 653 call get_ambient_level ; get ambient light level and set max_CCPR1L |
| 654 banksel isr_backup ; back to ISR default bank (for safety only) | |
| 655 | |
| 656 rcall isr_battery_gauge ; calculate the current charge consumption and add it to the battery gauge | |
| 657 rcall isr_update_uptime ; increment overall OSTC uptime | |
| 658 rcall isr_update_timeout ; process the timeout timer | |
| 659 | |
| 646 | 660 movff opt_brightness_surface,brightness ; copy brightness - will be overwritten with opt_brightness_dive if in dive mdoe |
| 623 | 661 btfsc divemode ; in dive mode? |
| 662 rcall isr_divemode_1sec ; YES - do the every second dive mode tasks | |
| 663 | |
| 629 | 664 ; increment surface interval counted in seconds |
| 623 | 665 btfsc divemode ; in dive mode? |
| 666 btfsc simulatormode ; YES - in simulator mode? | |
| 629 | 667 rcall inc_surface_interval_secs ; NO - YES - increment the surface interval (seconds timer) |
| 668 | |
| 669 ; reset the surface interval timers if requested | |
| 670 btfsc reset_surface_interval ; shall reset both surface interval timers? | |
| 634 | 671 rcall rst_surface_interval ; YES |
| 0 | 672 |
| 623 | 673 ; reset the timebase if requested |
| 674 btfss reset_timebase ; shall reset the timebase? | |
| 675 bra isr_rtcc_3 ; NO | |
| 676 bcf reset_timebase ; YES - clear request flag | |
| 677 clrf eventbase ; - clear all pending events | |
| 678 clrf timebase ; - clear all timebase flags | |
| 679 clrf timebase_secs ; - clear seconds timer | |
| 680 clrf timebase_mins ; - clear minutes timer | |
| 681 clrf simulator_time ; - clear minutes timer of simulator runtime as well | |
| 682 bsf trigger_half_second ; - set flag for a new 1/2 second has begun | |
| 683 bsf trigger_full_second ; - set flag for a new 1/1 second has begun | |
| 684 return ; - done | |
| 685 | |
| 686 isr_rtcc_3: | |
| 687 ; count-up the 2 seconds timebase timer | |
| 688 btg timebase_1sec ; toggle the 1 second timer bit | |
| 689 btfss timebase_1sec ; did it toggled 1 -> 0 ? | |
| 690 btg timebase_2sec ; YES - toggle the 2 seconds timer bit | |
| 691 | |
| 692 ; count-up the seconds timer | |
| 693 incf timebase_secs,F ; increment seconds timer (may temporary become 60 here) | |
| 694 movlw .59 ; max. for seconds timer | |
| 695 cpfsgt timebase_secs ; seconds timer > max.? | |
| 696 return ; NO - done | |
| 0 | 697 |
| 623 | 698 ; new full minute |
| 629 | 699 clrf timebase_secs ; reset timer |
| 700 bsf trigger_full_minute ; set flag for a new minute has begun | |
| 623 | 701 |
| 629 | 702 ; increment surface interval counted in minutes |
| 703 btfsc divemode ; in dive mode? | |
| 704 btfsc simulatormode ; YES - in simulator mode? | |
| 705 rcall inc_surface_interval_mins ; NO - YES - increment surface interval (minutes timer) | |
| 623 | 706 |
| 629 | 707 btfss simulatormode ; in simulator mode? |
| 708 bra isr_rtcc_4 ; NO | |
| 709 infsnz simulator_time,F ; YES - increment real runtime of the simulator, did wrap around (became zero)? | |
| 710 setf simulator_time ; YES - disallow wrap-around, keep at 255 instead | |
| 0 | 711 |
| 623 | 712 isr_rtcc_4: |
| 629 | 713 incf timebase_mins,F ; increment minutes timer |
| 714 movlw .59 ; max. for minutes timer | |
| 715 cpfsgt timebase_mins ; minutes timer > max.? | |
| 716 return ; NO - done | |
| 623 | 717 |
| 718 ; new full hour | |
| 629 | 719 clrf timebase_mins ; YES - reset timer |
| 720 bsf trigger_full_hour ; - set flag for a new hour has begun | |
| 721 return ; - done | |
| 623 | 722 |
| 723 ; increment overall OSTC uptime | |
| 724 isr_update_uptime: | |
| 634 | 725 incf uptime+0,F ; uptime++ |
| 726 clrf WREG ; ... | |
| 727 addwfc uptime+1,F ; ... | |
| 728 addwfc uptime+2,F ; ... | |
| 729 addwfc uptime+3,F ; ... | |
| 730 return ; done | |
| 582 | 731 |
| 623 | 732 ; process the timeout timer |
| 733 isr_update_timeout: | |
| 634 | 734 btfsc restart_timeout ; shall restart the timeout? |
| 623 | 735 bra isr_update_timeout_1 ; YES |
| 736 tstfsz isr_timeout_timer ; NO - timeout timer already at zero? | |
| 634 | 737 decfsz isr_timeout_timer,F ; NO - decrement timer, reached zero now? |
| 623 | 738 return ; YES / NO - nothing further to do |
| 739 bsf trigger_timeout ; YES - set timeout flag | |
| 740 return ; - done | |
| 741 isr_update_timeout_1: | |
| 634 | 742 bcf restart_timeout ; clear request flag |
| 623 | 743 bcf trigger_timeout ; clear pending timeout trigger, if any |
| 744 movff isr_timeout_reload,isr_timeout_timer ; reload timer | |
| 745 return ; done | |
| 0 | 746 |
| 634 | 747 |
| 748 ;----------------------------------------------------------------------------- | |
| 749 ; Calculate Charge drawn from the Battery | |
| 623 | 750 ; |
| 751 isr_battery_gauge: | |
| 752 btfsc block_battery_gauge ; access to battery gauge suspended? | |
| 753 return ; YES - done | |
| 754 MOVLI current_sleepmode,isr_mpr ; NO - default to sleep mode with 100µA/3600 -> nAs | |
| 755 btfss sleepmode ; - in sleep mode? | |
| 634 | 756 rcall isr_battery_gauge2 ; NO - compute current consumption into isr_lo and isr_hi |
| 757 movf isr_mpr+0,W ; - 48 bit add of isr_mpr:2 to battery_gauge:6 | |
| 758 addwf battery_gauge+0,F ; - ... | |
| 759 movf isr_mpr+1,W ; - ... | |
| 760 addwfc battery_gauge+1,F ; - ... | |
| 761 clrf WREG ; - ... | |
| 762 addwfc battery_gauge+2,F ; - ... | |
| 763 addwfc battery_gauge+3,F ; - ... | |
| 764 addwfc battery_gauge+4,F ; - ... | |
| 765 addwfc battery_gauge+5,F ; - ... | |
| 766 return ; - done | |
| 582 | 767 |
| 634 | 768 |
| 769 ;----------------------------------------------------------------------------- | |
| 770 ; Helper Function - compute current Consumption | |
| 771 ; | |
| 0 | 772 isr_battery_gauge2: |
| 634 | 773 ; Set consumption rate in nAs (nano Ampere x seconds) |
| 0 | 774 ; Example: |
| 623 | 775 ; MOVLI .55556,isr_mpr ; 0.2 Ah / 3600 seconds per hour * 1e9s = nAs |
| 776 ; | |
| 777 ; Remark: although all the constants are named current_xxxx, in reality they mean charge! | |
| 0 | 778 |
| 623 | 779 ; Calculate current consumption for LED backlight: 47*CCPR1L+272 (according to values in hwos.inc: 115*CCPR1L+216) |
| 631 | 780 movlw .70 ; screen type 3 has a fix backlight current slope |
| 781 btfss screen_type3 ; does the OSTC have a screen type 3 ? | |
| 782 movf CCPR1L,W ; NO - for screen types 0, 1 and 2 get the slope from CCPR1L | |
| 783 mullw current_backlight_multi ; multiply with backlight factor current_backlight_multi | |
| 784 ADDLI current_backlight_offset,PRODL ; add backlight offset current_backlight_offset | |
| 623 | 785 MOVII PRODL,isr_mpr ; copy result to isr_mpr |
| 0 | 786 |
| 634 | 787 ; add current for CPU and GPU |
| 623 | 788 ; cpu_speed_state = ECO 3.10 mA -> 861 nAs |
| 789 ; = NORMAL 5.50 mA -> 1528 nAs | |
| 790 ; = FASTEST 8.04 mA -> 2233 nAs | |
| 791 btfss speed_is_eco ; speed = eco ? | |
| 792 bra isr_battery_gauge3 ; NO | |
| 793 ADDLI current_speed_eco,isr_mpr ; YES - add current_speed_eco to isr_mpr | |
| 582 | 794 bra isr_battery_gauge5 |
| 0 | 795 isr_battery_gauge3: |
| 623 | 796 btfss speed_is_normal ; speed = normal? |
| 797 bra isr_battery_gauge4 ; NO | |
| 798 ADDLI current_speed_normal,isr_mpr ; YES - add current_speed_normal to isr_mpr | |
| 582 | 799 bra isr_battery_gauge5 |
| 0 | 800 isr_battery_gauge4: |
| 623 | 801 ADDLI current_speed_fastest,isr_mpr ; speed is fastest, add current_speed_fastest to isr_mpr |
| 0 | 802 isr_battery_gauge5: |
| 623 | 803 btfss ir_power ; IR enabled? |
| 804 bra isr_battery_gauge6 ; NO | |
| 805 ADDLI current_ir_receiver,isr_mpr ; YES - add current_ir_receiver to isr_mpr | |
| 0 | 806 isr_battery_gauge6: |
| 623 | 807 btfss compass_enabled ; compass active? |
| 808 bra isr_battery_gauge7 ; NO | |
| 809 ADDLI current_compass,isr_mpr ; YES - add current_compass to isr_mpr | |
| 0 | 810 isr_battery_gauge7: |
| 634 | 811 return ; done |
| 0 | 812 |
| 623 | 813 |
| 634 | 814 ;----------------------------------------------------------------------------- |
| 815 ; Every Second Tasks while in Dive Mode | |
| 623 | 816 ; |
| 0 | 817 isr_divemode_1sec: |
| 646 | 818 movff opt_brightness_divemode,brightness ; copy brightness for dive mode |
| 623 | 819 decfsz sampling_timer,F ; decrement sampling timer, became zero? |
| 820 bra isr_divemode_1sec_1 ; NO | |
| 821 bsf trigger_sample_divedata ; YES - set trigger flag for sampling dive data | |
| 822 movff sampling_rate,sampling_timer; - reload timer | |
| 0 | 823 |
| 623 | 824 isr_divemode_1sec_1: |
| 825 btfss reset_timebase ; shall reset the timebase? (request flag will be cleared later) | |
| 826 bra isr_divemode_1sec_2 ; NO | |
| 827 CLRI total_divetime_secs ; YES - reset total dive time, seconds (2 byte) | |
| 828 clrf counted_divetime_secs ; - reset counted dive time, seconds (1 byte) | |
| 829 CLRI counted_divetime_mins ; - reset counted dive time, minutes (2 byte) | |
| 830 clrf apnoe_dive_secs ; - reset apnoe dive time, seconds (1 byte) | |
| 831 clrf apnoe_dive_mins ; - reset apnoe dive time, minutes (1 byte) | |
| 832 bcf apnoe_at_surface ; - apnoe mode starts in submerged state | |
| 833 return ; - done | |
| 582 | 834 |
| 623 | 835 isr_divemode_1sec_2: |
| 836 INCI total_divetime_secs ; increase total dive time (regardless of start_dive_threshold) | |
| 837 btfss count_divetime ; shall the dive time be counted (regarding start_dive_threshold)? | |
| 629 | 838 bra isr_divemode_1sec_4 ; NO - too shallow / apnoe at surface |
| 623 | 839 incf counted_divetime_secs,F ; YES - increase dive time (displayed dive time) |
| 840 movlw d'59' ; - 60 seconds make a minute | |
| 841 cpfsgt counted_divetime_secs ; - next full minute reached? | |
| 629 | 842 bra isr_divemode_1sec_3 ; NO - continue |
| 623 | 843 clrf counted_divetime_secs ; YES - reset seconds to 0 |
| 844 INCI counted_divetime_mins ; - increase dive minutes | |
| 845 bsf divetime_longer_1min ; - set flag for dive time exceeding 1 minute | |
| 629 | 846 ;bra isr_divemode_1sec_3 ; - continue |
| 0 | 847 |
| 623 | 848 isr_divemode_1sec_3: ; submerged |
| 849 btfss FLAG_apnoe_mode ; in apnoe mode? | |
| 850 return ; NO - done | |
| 851 btfss apnoe_at_surface ; - been at surface before? | |
| 852 bra isr_divemode_1sec_3a ; NO - increment the dive time | |
| 853 bcf apnoe_at_surface ; YES - a new dive has begun | |
| 854 bsf apnoe_new_dive ; - signal a new dive has begun | |
| 855 clrf apnoe_surface_secs ; - clear surface seconds | |
| 856 clrf apnoe_surface_mins ; - clear surface minutes | |
| 857 clrf apnoe_dive_secs ; - clear dive seconds | |
| 858 clrf apnoe_dive_mins ; - clear dive minutes | |
| 859 MOVII pressure_rel_cur,pressure_rel_max ; - reset max pressure to current pressure | |
| 860 bsf trigger_pres_max_changed ; - signal a new maximum pressure | |
| 861 isr_divemode_1sec_3a: | |
| 862 incf apnoe_dive_secs,F ; increment dive time, seconds | |
| 863 movlw d'59' ; 60 seconds make a minute | |
| 864 cpfsgt apnoe_dive_secs ; next full minute reached? | |
| 865 return ; NO - done | |
| 866 clrf apnoe_dive_secs ; YES - reset seconds to 0 | |
| 867 incf apnoe_dive_mins,F ; - increment dive time, minutes | |
| 868 return ; - done | |
| 0 | 869 |
| 623 | 870 isr_divemode_1sec_4: ; at surface |
| 646 | 871 movff opt_brightness_surface,brightness ; copy brightness |
| 623 | 872 btfss FLAG_apnoe_mode ; in apnoe mode? |
| 873 return ; NO - done | |
| 874 bsf apnoe_at_surface ; YES - memorize been at the surface | |
| 875 incf apnoe_surface_secs,F ; - increment surface time, seconds | |
| 876 movlw d'59' ; - 60 seconds make a minute | |
| 877 cpfsgt apnoe_surface_secs ; - next full minute reached? | |
| 878 return ; NO - done | |
| 879 clrf apnoe_surface_secs ; YES - reset seconds to 0 | |
| 880 incf apnoe_surface_mins,F ; - increment surface time, minutes | |
| 881 return ; - done | |
| 882 | |
| 883 | |
| 634 | 884 ;----------------------------------------------------------------------------- |
| 885 ; Helper Function - BCD to Binary conversion | |
| 886 ; | |
| 623 | 887 ; Input WREG = value in BCD |
| 888 ; Output WREG = value in binary | |
| 889 ; | |
| 890 isr_rtcc_convert_BCD_DEC: | |
| 634 | 891 movwf isr_lo ; copy BCD to isr_lo |
| 892 swapf isr_lo, W ; create swapped copy in WREG | |
| 893 andlw 0x0F ; keep only the tens | |
| 894 rlncf WREG, W ; WREG = 2 * tens | |
| 623 | 895 subwf isr_lo, F ; 16 * tens + ones - 2*tens |
| 896 subwf isr_lo, F ; 14 * tens + ones - 2*tens | |
| 897 subwf isr_lo, W ; 12 * tens + ones - 2*tens | |
| 634 | 898 return ; done |
| 0 | 899 |
| 900 | |
| 634 | 901 ;----------------------------------------------------------------------------- |
| 902 ; Check Buttons | |
| 623 | 903 ; |
| 582 | 904 isr_switch_right: |
| 640 | 905 bcf INTCON,INT0IE ; disable external interrupt 0 |
| 906 | |
| 646 | 907 btfsc button_hold_down_allowed ; ignore for mechanical push buttons |
| 640 | 908 bra isr_switch_right2 |
| 909 btfsc T4CON,TMR4ON ; Timer4 running? | |
| 910 bra timer4_restart ; Yes, restart | |
| 911 isr_switch_right2: | |
| 912 | |
| 582 | 913 btfss flip_screen ; 180° flipped? |
| 634 | 914 bsf switch_right ; NO - set flag for right button |
| 582 | 915 btfsc flip_screen ; 180° flipped? |
| 634 | 916 bsf switch_left ; YES - set flag for left button |
| 917 bra isr_switch_common ; continue with common part | |
| 0 | 918 |
| 582 | 919 isr_switch_left: |
| 640 | 920 bcf INTCON3,INT1IE ; disable external interrupt 1 |
| 921 | |
| 646 | 922 btfsc button_hold_down_allowed ; ignore for mechanical push buttons |
| 640 | 923 bra isr_switch_left2 |
| 924 btfsc T4CON,TMR4ON ; Timer4 running? | |
| 925 bra timer4_restart ; Yes, restart | |
| 926 isr_switch_left2: | |
| 927 | |
| 582 | 928 btfss flip_screen ; 180° flipped? |
| 634 | 929 bsf switch_left ; NO - set flag for left button |
| 582 | 930 btfsc flip_screen ; 180° flipped? |
| 634 | 931 bsf switch_right ; YES - set flag for right button |
| 932 ;bra isr_switch_common ; continue with common part | |
| 623 | 933 |
| 0 | 934 isr_switch_common: |
| 646 | 935 btfss button_hold_down_allowed ; ignore for mechanical push buttons |
| 640 | 936 bsf T4CON,TMR4ON ; Start timer 4 |
| 937 | |
| 634 | 938 btfsc tmr5_preemtion_allowed ; timer 5 preemption allowed? |
| 939 bsf PIR5,TMR5IF ; YES - preempt timer 5 | |
| 940 movlw TMR1H_VALUE_FIRST ; load timer 1 (in steps of 7.8125 ms) | |
| 623 | 941 movwf TMR1H ; ... |
| 634 | 942 clrf TMR1L ; ... |
| 604 | 943 bsf T1CON,TMR1ON ; start timer 1 |
| 640 | 944 bcf INTCON3,INT1IF ; clear ext. int 1 request |
| 945 bcf INTCON,INT0IF ; clear ext. int 0 request | |
| 634 | 946 return ; done |
| 0 | 947 |
| 623 | 948 |
| 634 | 949 ;----------------------------------------------------------------------------- |
| 950 ; Button hold-down Interrupt | |
| 623 | 951 ; |
| 0 | 952 timer1int: |
| 634 | 953 bcf PIR1,TMR1IF ; clear timer 1 IRQ request |
| 640 | 954 bcf INTCON,INT0IF ; clear ext. int 0 request |
| 955 bcf INTCON3,INT1IF ; clear ext. int 1 request | |
| 634 | 956 |
| 451 | 957 ; digital |
| 604 | 958 btfss switch_left1 ; left button hold-down? |
| 959 bra timer1int_left ; YES | |
| 960 btfss switch_right2 ; right button hold-down? | |
| 961 bra timer1int_right ; YES | |
| 582 | 962 |
| 623 | 963 ; analog |
| 604 | 964 btfsc analog_sw2_pressed ; left button hold-down? |
| 965 bra timer1int_left ; YES | |
| 966 btfsc analog_sw1_pressed ; right button hold-down? | |
| 967 bra timer1int_right ; YES | |
| 582 | 968 |
| 634 | 969 ; no button hold-down, stop timer 1 |
| 604 | 970 bcf T1CON,TMR1ON ; stop timer 1 |
| 634 | 971 bsf INTCON,INT0IE ; enable INT0 IRQ |
| 972 bsf INTCON3,INT1IE ; enable INT1 IRQ | |
| 451 | 973 return |
| 0 | 974 |
| 975 timer1int_left: | |
| 582 | 976 btfss flip_screen ; 180° flipped? |
| 634 | 977 bsf switch_left ; set flag for left button |
| 582 | 978 btfsc flip_screen ; 180° flipped? |
| 634 | 979 bsf switch_right ; set flag for right button |
| 604 | 980 bra timer1int_common ; continue |
| 623 | 981 |
| 0 | 982 timer1int_right: |
| 582 | 983 btfss flip_screen ; 180° flipped? |
| 634 | 984 bsf switch_right ; set flag for right button |
| 582 | 985 btfsc flip_screen ; 180° flipped? |
| 634 | 986 bsf switch_left ; set flag for left button |
| 623 | 987 ;bra timer1int_common ; continue |
| 988 | |
| 634 | 989 timer1int_common: ; load timer 1 for next button press |
| 623 | 990 movlw TMR1H_VALUE_CONT ; default to surface mode value |
| 991 btfsc divemode ; in dive mode? | |
| 992 movlw TMR1H_VALUE_CONT_DIVE ; YES - overwrite with dive mode value | |
| 993 movwf TMR1H ; write value to timer, high byte | |
| 634 | 994 clrf TMR1L ; write value to timer, low byte (zero) |
| 995 return ; done (timer1 kept running) | |
| 0 | 996 |
| 623 | 997 |
| 634 | 998 ;----------------------------------------------------------------------------- |
| 999 ; Increment Surface Interval (counted in minutes and in seconds) | |
| 623 | 1000 ; |
| 1001 ; int_O_desaturation_time is only computed while in start, surface mode, | |
| 629 | 1002 ; menue_tree or ghostwriter. So the ISR may clock surface_interval_mins |
| 634 | 1003 ; past the actual surface interval time. But TFT_surf_cv_lastdive will |
| 629 | 1004 ; check int_O_desaturation_time and in case int_O_desaturation_time is |
| 1005 ; zero it will not show surface_interval_mins but surface_interval_secs instead. | |
| 1006 ; Thus the glitch will remain invisible. | |
| 623 | 1007 ; |
| 634 | 1008 inc_surface_interval_secs: ; called every second when not in dive mode |
| 1009 incf surface_interval_secs+0,F ; increment the lowest byte | |
| 1010 clrf WREG ; clear WREG | |
| 1011 addwfc surface_interval_secs+1,F ; add carry from byte before, if it did wrap-around | |
| 1012 addwfc surface_interval_secs+2,F ; add carry from byte before, if it did wrap-around | |
| 1013 addwfc surface_interval_secs+3,F ; add carry from byte before, if it did wrap-around | |
| 1014 return ; done | |
| 629 | 1015 |
| 634 | 1016 inc_surface_interval_mins: ; called every minute when not in dive mode |
| 1017 movff int_O_desaturation_time+0,isr_lo ; get desaturation time, low byte | |
| 1018 movff int_O_desaturation_time+1,WREG ; get desaturation time, high byte | |
| 1019 iorwf isr_lo,W ; inclusive-or low & high byte, desaturation time = 0 ? | |
| 1020 bz clr_surface_interval_mins ; YES - reset surface interval minutes counter | |
| 1021 INCI surface_interval_mins ; NO - increment surface interval | |
| 1022 return ; - done | |
| 629 | 1023 |
| 631 | 1024 rst_surface_interval: |
| 629 | 1025 bcf reset_surface_interval ; reset request flag |
| 631 | 1026 ; reset the surface interval counted in seconds |
| 629 | 1027 clrf surface_interval_secs+0 ; reset surface interval (seconds), lowest byte |
| 1028 clrf surface_interval_secs+1 ; ... | |
| 1029 clrf surface_interval_secs+2 ; ... | |
| 1030 clrf surface_interval_secs+3 ; reset surface interval (seconds), highest byte | |
| 631 | 1031 ; reset the surface interval counted in minutes |
| 629 | 1032 movff opt_diveTimeout,surface_interval_mins+0 ; set surface interval (minutes), low byte, to dive timeout offset |
| 1033 clrf surface_interval_mins+1 ; reset surface interval (minutes), high byte | |
| 631 | 1034 return ; done |
| 629 | 1035 |
| 631 | 1036 clr_surface_interval_mins: |
| 1037 clrf surface_interval_mins+0 ; reset surface interval (minutes), low byte | |
| 1038 clrf surface_interval_mins+1 ; reset surface interval (minutes), high byte | |
| 629 | 1039 return ; done |
| 1040 | |
| 634 | 1041 ;----------------------------------------------------------------------------- |
| 0 | 1042 |
| 582 | 1043 END |